pkgs/development/tools/cambalache/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitLab
   4 , python3
   5 , meson
   6 , ninja
   7 , pkg-config
   8 , gobject-introspection
   9 , desktop-file-utils
  10 , shared-mime-info
  11 , wrapGAppsHook
  12 , glib
  13 , gtk3
  14 , gtk4
  15 , libadwaita
  16 , libhandy
  17 , webkitgtk
  18 , nix-update-script
  19 }:
  20
  21 python3.pkgs.buildPythonApplication rec {
  22   pname = "cambalache";
  23   version = "0.10.3";
  24
  25   format = "other";
  26
  27   src = fetchFromGitLab {
  28     domain = "gitlab.gnome.org";
  29     owner = "jpu";
  30     repo = pname;
  31     rev = version;
  32     sha256 = "sha256-Xm8h3BBRibdLCeI/OeprF5dCCiNrfJCg7aE24uleCds=";
  33   };
  34
  35   nativeBuildInputs = [
  36     meson
  37     ninja
  38     pkg-config
  39     gobject-introspection # for setup hook
  40     desktop-file-utils # for update-desktop-database
  41     shared-mime-info # for update-mime-database
  42     wrapGAppsHook
  43   ];
  44
  45   pythonPath = with python3.pkgs; [
  46     pygobject3
  47     lxml
  48   ];
  49
  50   buildInputs = [
  51     glib
  52     gtk3
  53     gtk4
  54     webkitgtk
  55     # For extra widgets support.
  56     libadwaita
  57     libhandy
  58   ];
  59
  60   # Not compatible with gobject-introspection setup hooks.
  61   # https://github.com/NixOS/nixpkgs/issues/56943
  62   strictDeps = false;
  63
  64   # Prevent double wrapping.
  65   dontWrapGApps = true;
  66
  67   postPatch = ''
  68     patchShebangs postinstall.py
  69   '';
  70
  71   preFixup = ''
  72     # Let python wrapper use GNOME flags.
  73     makeWrapperArgs+=(
  74       # For broadway daemons
  75       --prefix PATH : "${lib.makeBinPath [ gtk3 gtk4 ]}"
  76       "''${gappsWrapperArgs[@]}"
  77     )
  78   '';
  79
  80   postFixup = ''
  81     # Wrap a helper script in an unusual location.
  82     wrapPythonProgramsIn "$out/${python3.sitePackages}/cambalache/priv/merengue" "$out $pythonPath"
  83   '';
  84
  85   passthru = {
  86     updateScript = nix-update-script {
  87       attrPath = pname;
  88     };
  89   };
  90
  91   meta = with lib; {
  92     homepage = "https://gitlab.gnome.org/jpu/cambalache";
  93     description = "RAD tool for GTK 4 and 3 with data model first philosophy";
  94     maintainers = teams.gnome.members;
  95     license = with licenses; [
  96       lgpl21Only # Cambalache
  97       gpl2Only # tools
  98     ];
  99     platforms = platforms.unix;
 100   };
 101 }