pkgs/games/clonehero/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , autoPatchelfHook
   5 , alsa-lib
   6 , gtk2
   7 , libXrandr
   8 , libXScrnSaver
   9 , udev
  10 , zlib
  11 }:
  12
  13 let
  14   name = "clonehero";
  15 in
  16 stdenv.mkDerivation rec {
  17   pname = "${name}-unwrapped";
  18   version = "0.23.2.2";
  19
  20   src = fetchurl {
  21     url = "http://dl.clonehero.net/${name}-v${lib.removePrefix "0" version}/${name}-linux.tar.gz";
  22     sha256 = "0k9jcnd55yhr42gj8cmysd18yldp4k3cpk4z884p2ww03fyfq7mi";
  23   };
  24
  25   outputs = [ "out" "doc" ];
  26
  27   nativeBuildInputs = [ autoPatchelfHook ];
  28
  29   buildInputs = [
  30     # Load-time libraries (loaded from DT_NEEDED section in ELF binary)
  31     gtk2
  32     stdenv.cc.cc.lib
  33     zlib
  34
  35     # Run-time libraries (loaded with dlopen)
  36     alsa-lib # ALSA sound
  37     libXrandr # X11 resolution detection
  38     libXScrnSaver # X11 screensaver prevention
  39     udev # udev input drivers
  40   ];
  41
  42   installPhase = ''
  43     mkdir -p "$out/bin" "$out/share"
  44     install -Dm755 ${name} "$out/bin"
  45     cp -r clonehero_Data "$out/share"
  46
  47     mkdir -p "$doc/share/${name}"
  48     cp README.txt "$doc/share/${name}"
  49   '';
  50
  51   # Patch required run-time libraries as load-time libraries
  52   #
  53   # Libraries found with:
  54   # > strings clonehero | grep '\.so'
  55   # and
  56   # > strace clonehero 2>&1 | grep '\.so'
  57   postFixup = ''
  58     patchelf \
  59       --add-needed libasound.so.2 \
  60       --add-needed libudev.so.1 \
  61       --add-needed libXrandr.so.2 \
  62       --add-needed libXss.so.1 \
  63       "$out/bin/${name}"
  64   '';
  65
  66   meta = with lib; {
  67     description = "Clone of Guitar Hero and Rockband-style games";
  68     homepage = "https://clonehero.net";
  69     license = licenses.unfree;
  70     maintainers = with maintainers; [ kira-bruneau ];
  71     platforms = [ "x86_64-linux" ];
  72   };
  73 }