pkgs/games/urbanterror/default.nix

   1 { lib, stdenv, fetchurl, unzip, SDL, libGLU, libGL, openal, curl, libXxf86vm }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "urbanterror";
   5   version = "4.3.4";
   6
   7   srcs =
   8     [ (fetchurl {
   9          url = "http://cdn.urbanterror.info/urt/43/releases/zips/UrbanTerror434_full.zip";
  10          sha256 = "1rx4nnndsk88nvd7k4p35cw6znclkkzm2bl5j6vn6mjjdk66jrki";
  11        })
  12       (fetchurl {
  13          url = "https://github.com/FrozenSand/ioq3-for-UrbanTerror-4/archive/release-${version}.zip";
  14          sha256 = "1s9pmw7rbnzwzl1llcs0kr2krf4daf8hhnz1j89qk4bq9a9qfp71";
  15        })
  16     ];
  17
  18   nativeBuildInputs = [ unzip ];
  19   buildInputs = [ SDL libGL libGLU openal curl libXxf86vm ];
  20   sourceRoot = "ioq3-for-UrbanTerror-4-release-${version}";
  21
  22   configurePhase = ''
  23     echo "USE_OPENAL = 1" > Makefile.local
  24     echo "USE_OPENAL_DLOPEN = 0" >> Makefile.local
  25     echo "USE_CURL = 1" >> Makefile.local
  26     echo "USE_CURL_DLOPEN = 0" >> Makefile.local
  27   '';
  28
  29   installPhase = ''
  30     destDir="$out/opt/urbanterror"
  31     mkdir -p "$destDir"
  32     mkdir -p "$out/bin"
  33     cp -v build/release-linux-*/Quake3-UrT.* \
  34           "$destDir/Quake3-UrT"
  35     cp -v build/release-linux-*/Quake3-UrT-Ded.* \
  36           "$destDir/Quake3-UrT-Ded"
  37     cp -rv ../UrbanTerror43/q3ut4 "$destDir"
  38     cat << EOF > "$out/bin/urbanterror"
  39     #! ${stdenv.shell}
  40     cd "$destDir"
  41     exec ./Quake3-UrT "\$@"
  42     EOF
  43     chmod +x "$out/bin/urbanterror"
  44     cat << EOF > "$out/bin/urbanterror-ded"
  45     #! ${stdenv.shell}
  46     cd "$destDir"
  47     exec ./Quake3-UrT-Ded "\$@"
  48     EOF
  49     chmod +x "$out/bin/urbanterror-ded"
  50   '';
  51
  52   postFixup = ''
  53     p=$out/opt/urbanterror/Quake3-UrT
  54     cur_rpath=$(patchelf --print-rpath $p)
  55     patchelf --set-rpath $cur_rpath:${libGL}/lib:${libGLU}/lib $p
  56   '';
  57
  58   hardeningDisable = [ "format" ];
  59
  60   meta = with lib; {
  61     description = "A multiplayer tactical FPS on top of Quake 3 engine";
  62     longDescription = ''
  63       Urban Terror is a free multiplayer first person shooter developed by
  64       FrozenSand, that (thanks to the ioquake3-code) does not require
  65       Quake III Arena anymore. Urban Terror can be described as a Hollywood
  66       tactical shooter; somewhat realism based, but the motto is "fun over
  67       realism". This results in a very unique, enjoyable and addictive game.
  68     '';
  69     homepage = "http://www.urbanterror.info";
  70     license = licenses.unfreeRedistributable;
  71     maintainers = with maintainers; [ astsmtl ];
  72     platforms = platforms.linux;
  73     hydraPlatforms = [];
  74   };
  75 }