pkgs/tools/misc/broot/default.nix

   1 { lib
   2 , stdenv
   3 , rustPlatform
   4 , fetchCrate
   5 , installShellFiles
   6 , makeWrapper
   7 , pkg-config
   8 , libgit2
   9 , oniguruma
  10 , libiconv
  11 , Security
  12 , xorg
  13 , zlib
  14 }:
  15
  16 rustPlatform.buildRustPackage rec {
  17   pname = "broot";
  18   version = "1.16.2";
  19
  20   src = fetchCrate {
  21     inherit pname version;
  22     sha256 = "sha256-5R5pGCn4CJU2kGPiu6PpUBxr0/02hOwN1ikns2pvGA0=";
  23   };
  24
  25   cargoHash = "sha256-0d7EMWc/PU9kDgfTVc1SWYYym9UEULwR1X3qIW+zvjM=";
  26
  27   nativeBuildInputs = [
  28     installShellFiles
  29     makeWrapper
  30     pkg-config
  31   ];
  32
  33   buildInputs = [ libgit2 oniguruma xorg.libxcb ] ++ lib.optionals stdenv.isDarwin [
  34     libiconv
  35     Security
  36     zlib
  37   ];
  38
  39   RUSTONIG_SYSTEM_LIBONIG = true;
  40
  41   postPatch = ''
  42     # Fill the version stub in the man page. We can't fill the date
  43     # stub reproducibly.
  44     substitute man/page man/broot.1 \
  45       --replace "#version" "${version}"
  46   '';
  47
  48   postInstall = ''
  49     # Do not nag users about installing shell integration, since
  50     # it is impure.
  51     wrapProgram $out/bin/broot \
  52       --set BR_INSTALL no
  53
  54     # Install shell function for bash.
  55     $out/bin/broot --print-shell-function bash > br.bash
  56     install -Dm0444 -t $out/etc/profile.d br.bash
  57
  58     # Install shell function for zsh.
  59     $out/bin/broot --print-shell-function zsh > br.zsh
  60     install -Dm0444 br.zsh $out/share/zsh/site-functions/br
  61
  62     # Install shell function for fish
  63     $out/bin/broot --print-shell-function fish > br.fish
  64     install -Dm0444 -t $out/share/fish/vendor_functions.d br.fish
  65
  66     # install shell completion files
  67     OUT_DIR=$releaseDir/build/broot-*/out
  68
  69     installShellCompletion --bash $OUT_DIR/{br,broot}.bash
  70     installShellCompletion --fish $OUT_DIR/{br,broot}.fish
  71     installShellCompletion --zsh $OUT_DIR/{_br,_broot}
  72
  73     installManPage man/broot.1
  74   '';
  75
  76   doInstallCheck = true;
  77   installCheckPhase = ''
  78     $out/bin/broot --version | grep "${version}"
  79   '';
  80
  81   meta = with lib; {
  82     description = "An interactive tree view, a fuzzy search, a balanced BFS descent and customizable commands";
  83     homepage = "https://dystroy.org/broot/";
  84     changelog = "https://github.com/Canop/broot/releases/tag/v${version}";
  85     maintainers = with maintainers; [ dywedir ];
  86     license = with licenses; [ mit ];
  87   };
  88 }