pkgs/tools/security/asc-key-to-qr-code-gif/default.nix

   1 { lib, stdenv, fetchFromGitHub, imagemagick, qrencode
   2 , testQR ? false, zbar ? null
   3 }:
   4
   5 assert testQR -> zbar != false;
   6
   7 stdenv.mkDerivation {
   8   pname = "asc-key-to-qr-code-gif";
   9   version = "20180613";
  10
  11   src = fetchFromGitHub {
  12     owner = "yishilin14";
  13     repo = "asc-key-to-qr-code-gif";
  14     rev = "5b7b239a0089a5269444cbe8a651c99dd43dce3f";
  15     sha256 = "0yrc302a2fhbzryb10718ky4fymfcps3lk67ivis1qab5kbp6z8r";
  16   };
  17
  18   dontBuild = true;
  19   dontStrip = true;
  20   dontPatchELF = true;
  21
  22   preInstall = let
  23     substitutions = [
  24       ''--replace "convert" "${imagemagick}/bin/convert"''
  25       ''--replace "qrencode" "${qrencode.bin}/bin/qrencode"''
  26     ] ++ lib.optionals testQR [
  27       ''--replace "hash zbarimg" "true"'' # hash does not work on NixOS
  28       ''--replace "$(zbarimg --raw" "$(${zbar.out}/bin/zbarimg --raw"''
  29     ];
  30   in ''
  31     substituteInPlace asc-to-gif.sh ${lib.concatStringsSep " " substitutions}
  32   '';
  33
  34   installPhase = ''
  35     mkdir -p $out/bin
  36     cp * $out/bin/
  37   '';
  38
  39   meta = with lib; {
  40     homepage = "https://github.com/yishilin14/asc-key-to-qr-code-gif";
  41     description = "Convert ASCII-armored PGP keys to animated QR code";
  42     platforms = platforms.unix;
  43     maintainers = with maintainers; [ asymmetric ];
  44   };
  45 }