pkgs/tools/security/step-ca/default.nix

   1 { stdenv
   2 , lib
   3 , fetchFromGitHub
   4 , buildGoModule
   5 , coreutils
   6 , pcsclite
   7 , PCSC
   8 , pkg-config
   9 , hsmSupport ? true
  10 , nixosTests
  11 }:
  12
  13 buildGoModule rec {
  14   pname = "step-ca";
  15   version = "0.22.1";
  16
  17   src = fetchFromGitHub {
  18     owner = "smallstep";
  19     repo = "certificates";
  20     rev = "v${version}";
  21     sha256 = "sha256-iWThTFH36NNjO9Acx5QyxJrUzKFl7vD/seWF/Rz05CU=";
  22   };
  23
  24   vendorSha256 = "sha256-AcjICy991WPQyXp/9j6rgedg4FTYXilH7O4dy8gGYq8=";
  25
  26   ldflags = [ "-buildid=" ];
  27
  28   nativeBuildInputs = lib.optionals hsmSupport [ pkg-config ];
  29
  30   buildInputs =
  31     lib.optionals (hsmSupport && stdenv.isLinux) [ pcsclite ]
  32     ++ lib.optionals (hsmSupport && stdenv.isDarwin) [ PCSC ];
  33
  34   postPatch = ''
  35     substituteInPlace systemd/step-ca.service --replace "/bin/kill" "${coreutils}/bin/kill"
  36   '';
  37
  38   preBuild = ''
  39     ${lib.optionalString (!hsmSupport) "export CGO_ENABLED=0"}
  40   '';
  41
  42   postInstall = ''
  43     install -Dm444 -t $out/lib/systemd/system systemd/step-ca.service
  44   '';
  45
  46   # Tests start http servers which need to bind to local addresses:
  47   # panic: httptest: failed to listen on a port: listen tcp6 [::1]:0: bind: operation not permitted
  48   __darwinAllowLocalNetworking = true;
  49
  50   passthru.tests.step-ca = nixosTests.step-ca;
  51
  52   meta = with lib; {
  53     description = "A private certificate authority (X.509 & SSH) & ACME server for secure automated certificate management, so you can use TLS everywhere & SSO for SSH";
  54     homepage = "https://smallstep.com/certificates/";
  55     license = licenses.asl20;
  56     maintainers = with maintainers; [ cmcdragonkai mohe2015 techknowlogick ];
  57   };
  58 }