nixos/modules/services/x11/display-managers/startx.nix

   1 {
   2   config,
   3   lib,
   4   pkgs,
   5   ...
   6 }:
   7
   8 with lib;
   9
  10 let
  11
  12   cfg = config.services.xserver.displayManager.startx;
  13
  14 in
  15
  16 {
  17
  18   ###### interface
  19
  20   options = {
  21     services.xserver.displayManager.startx = {
  22       enable = mkOption {
  23         type = types.bool;
  24         default = false;
  25         description = ''
  26           Whether to enable the dummy "startx" pseudo-display manager,
  27           which allows users to start X manually via the "startx" command
  28           from a vt shell. The X server runs under the user's id, not as root.
  29           The user must provide a ~/.xinitrc file containing session startup
  30           commands, see startx(1). This is not automatically generated
  31           from the desktopManager and windowManager settings.
  32         '';
  33       };
  34     };
  35   };
  36
  37   ###### implementation
  38
  39   config = mkIf cfg.enable {
  40     services.xserver = {
  41       exportConfiguration = true;
  42     };
  43
  44     # Other displayManagers log to /dev/null because they're services and put
  45     # Xorg's stdout in the journal
  46     #
  47     # To send log to Xorg's default log location ($XDG_DATA_HOME/xorg/), we do
  48     # not specify a log file when running X
  49     services.xserver.logFile = mkDefault null;
  50
  51     # Implement xserverArgs via xinit's system-wide xserverrc
  52     environment.etc."X11/xinit/xserverrc".source = pkgs.writeShellScript "xserverrc" ''
  53       exec ${pkgs.xorg.xorgserver}/bin/X ${toString config.services.xserver.displayManager.xserverArgs} "$@"
  54     '';
  55     environment.systemPackages = with pkgs; [ xorg.xinit ];
  56   };
  57
  58 }