nixos/modules/services/x11/window-managers/qtile.nix

   1 { config, pkgs, lib, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfg = config.services.xserver.windowManager.qtile;
   7 in
   8
   9 {
  10   imports = [
  11     (mkRemovedOptionModule [ "services" "xserver" "windowManager" "qtile" "backend" ] "The qtile package now provides separate display sessions for both X11 and Wayland.")
  12   ];
  13
  14   options.services.xserver.windowManager.qtile = {
  15     enable = mkEnableOption "qtile";
  16
  17     package = mkPackageOption pkgs "qtile-unwrapped" { };
  18
  19     configFile = mkOption {
  20       type = with types; nullOr path;
  21       default = null;
  22       example = literalExpression "./your_config.py";
  23       description = ''
  24           Path to the qtile configuration file.
  25           If null, $XDG_CONFIG_HOME/qtile/config.py will be used.
  26       '';
  27     };
  28
  29     extraPackages = mkOption {
  30         type = types.functionTo (types.listOf types.package);
  31         default = _: [];
  32         defaultText = literalExpression ''
  33           python3Packages: with python3Packages; [];
  34         '';
  35         description = ''
  36           Extra Python packages available to Qtile.
  37           An example would be to include `python3Packages.qtile-extras`
  38           for additional unofficial widgets.
  39         '';
  40         example = literalExpression ''
  41           python3Packages: with python3Packages; [
  42             qtile-extras
  43           ];
  44         '';
  45       };
  46
  47     finalPackage = mkOption {
  48       type = types.package;
  49       visible = false;
  50       readOnly = true;
  51       description = "The resulting Qtile package, bundled with extra packages";
  52     };
  53   };
  54
  55   config = mkIf cfg.enable {
  56     services = {
  57       xserver.windowManager.qtile.finalPackage = pkgs.python3.pkgs.qtile.override { extraPackages = cfg.extraPackages pkgs.python3.pkgs; };
  58       displayManager.sessionPackages = [ cfg.finalPackage ];
  59     };
  60
  61     environment = {
  62       etc."xdg/qtile/config.py" = mkIf (cfg.configFile != null) { source = cfg.configFile; };
  63       systemPackages = [ cfg.finalPackage ];
  64     };
  65   };
  66 }