pkgs/applications/editors/emacs/build-support/elpa.nix

   1 # builder for Emacs packages built for packages.el
   2
   3 {
   4   lib,
   5   stdenv,
   6   emacs,
   7   texinfo,
   8   writeText,
   9 }:
  10
  11 let
  12   genericBuild = import ./generic.nix {
  13     inherit
  14       lib
  15       stdenv
  16       emacs
  17       texinfo
  18       writeText
  19       ;
  20   };
  21   libBuildHelper = import ./lib-build-helper.nix;
  22
  23 in
  24
  25 libBuildHelper.extendMkDerivation' genericBuild (
  26   finalAttrs:
  27
  28   {
  29     pname,
  30     dontUnpack ? true,
  31     meta ? { },
  32     ...
  33   }@args:
  34
  35   {
  36
  37     elpa2nix = args.elpa2nix or ./elpa2nix.el;
  38
  39     inherit dontUnpack;
  40
  41     installPhase =
  42       args.installPhase or ''
  43         runHook preInstall
  44
  45         emacs --batch -Q -l "$elpa2nix" \
  46             -f elpa2nix-install-package \
  47             "$src" "$out/share/emacs/site-lisp/elpa"
  48
  49         runHook postInstall
  50       '';
  51
  52     meta = {
  53       homepage = args.src.meta.homepage or "https://elpa.gnu.org/packages/${pname}.html";
  54     } // meta;
  55   }
  56
  57 )