pkgs/applications/editors/kakoune/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5 }:
   6
   7 stdenv.mkDerivation (finalAttrs: {
   8   pname = "kakoune-unwrapped";
   9   version = "2024.05.18";
  10   src = fetchFromGitHub {
  11     repo = "kakoune";
  12     owner = "mawww";
  13     rev = "v${finalAttrs.version}";
  14     hash = "sha256-1nYSVbvQ4tz1r8p7zCD6w/79haqpelb15qva9r3Fwew=";
  15   };
  16   makeFlags = [
  17     "debug=no"
  18     "PREFIX=${placeholder "out"}"
  19   ];
  20
  21   postPatch = ''
  22     echo "v${finalAttrs.version}" >.version
  23   '';
  24
  25   enableParallelBuilding = true;
  26
  27   doInstallCheck = true;
  28   installCheckPhase = ''
  29     $out/bin/kak -ui json -e "kill 0"
  30   '';
  31
  32   postInstall = ''
  33     # make share/kak/autoload a directory, so we can use symlinkJoin with plugins
  34     cd "$out/share/kak"
  35     autoload_target=$(readlink autoload)
  36     rm autoload
  37     mkdir autoload
  38     ln -s --relative "$autoload_target" autoload
  39   '';
  40
  41   meta = with lib; {
  42     homepage = "http://kakoune.org/";
  43     description = "Vim inspired text editor";
  44     license = licenses.publicDomain;
  45     mainProgram = "kak";
  46     maintainers = with maintainers; [ philiptaron ];
  47     platforms = platforms.unix;
  48   };
  49 })