pkgs/applications/radio/qdmr/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   installShellFiles,
   6   cmake,
   7   libxslt,
   8   docbook_xsl_ns,
   9   wrapQtAppsHook,
  10   libusb1,
  11   qtlocation,
  12   qtserialport,
  13   qttools,
  14   qtbase,
  15   yaml-cpp,
  16 }:
  17
  18 let
  19   inherit (stdenv.hostPlatform) isLinux;
  20 in
  21
  22 stdenv.mkDerivation rec {
  23   pname = "qdmr";
  24   version = "0.12.0";
  25
  26   src = fetchFromGitHub {
  27     owner = "hmatuschek";
  28     repo = "qdmr";
  29     rev = "v${version}";
  30     hash = "sha256-8NV0+M9eMcvkP3UERDkaimbapTKxB4rYRLbHZjzG4Ws=";
  31   };
  32
  33   nativeBuildInputs = [
  34     cmake
  35     libxslt
  36     wrapQtAppsHook
  37     installShellFiles
  38   ];
  39
  40   buildInputs = [
  41     libusb1
  42     qtlocation
  43     qtserialport
  44     qttools
  45     qtbase
  46     yaml-cpp
  47   ];
  48
  49   postPatch = lib.optionalString isLinux ''
  50     substituteInPlace doc/docbook_man.debian.xsl \
  51       --replace /usr/share/xml/docbook/stylesheet/docbook-xsl/manpages/docbook\.xsl ${docbook_xsl_ns}/xml/xsl/docbook/manpages/docbook.xsl
  52   '';
  53
  54   cmakeFlags = [
  55     "-DBUILD_MAN=ON"
  56     "-DINSTALL_UDEV_RULES=OFF"
  57   ];
  58
  59   postInstall = ''
  60     installManPage doc/dmrconf.1 doc/qdmr.1
  61     mkdir -p "$out/etc/udev/rules.d"
  62     cp ${src}/dist/99-qdmr.rules $out/etc/udev/rules.d/
  63   '';
  64
  65   meta = {
  66     description = "GUI application and command line tool for programming DMR radios";
  67     homepage = "https://dm3mat.darc.de/qdmr/";
  68     license = lib.licenses.gpl3Plus;
  69     maintainers = with lib.maintainers; [ _0x4A6F ];
  70     platforms = lib.platforms.linux;
  71   };
  72 }