pkgs/applications/virtualization/cri-o/default.nix

   1 {
   2   lib,
   3   btrfs-progs,
   4   buildGoModule,
   5   fetchFromGitHub,
   6   glibc,
   7   gpgme,
   8   installShellFiles,
   9   libapparmor,
  10   libseccomp,
  11   libselinux,
  12   lvm2,
  13   pkg-config,
  14   nixosTests,
  15 }:
  16
  17 buildGoModule rec {
  18   pname = "cri-o";
  19   version = "1.31.3";
  20
  21   src = fetchFromGitHub {
  22     owner = "cri-o";
  23     repo = "cri-o";
  24     rev = "v${version}";
  25     hash = "sha256-uoB5v+dl3895sW597f/Y49E2BJvy89871xu/rqWd7kw=";
  26   };
  27   vendorHash = null;
  28
  29   doCheck = false;
  30
  31   outputs = [
  32     "out"
  33     "man"
  34   ];
  35   nativeBuildInputs = [
  36     installShellFiles
  37     pkg-config
  38   ];
  39
  40   buildInputs =
  41     [
  42       btrfs-progs
  43       gpgme
  44       libapparmor
  45       libseccomp
  46       libselinux
  47       lvm2
  48     ]
  49     ++ lib.optionals (glibc != null) [
  50       glibc
  51       glibc.static
  52     ];
  53
  54   BUILDTAGS = "apparmor seccomp selinux containers_image_openpgp containers_image_ostree_stub";
  55   buildPhase = ''
  56     runHook preBuild
  57     make binaries docs BUILDTAGS="$BUILDTAGS"
  58     runHook postBuild
  59   '';
  60
  61   installPhase = ''
  62     runHook preInstall
  63     install -Dm755 bin/* -t $out/bin
  64
  65     for shell in bash fish zsh; do
  66       installShellCompletion --$shell completions/$shell/*
  67     done
  68
  69     install contrib/cni/*.conflist -Dt $out/etc/cni/net.d
  70     install crictl.yaml -Dt $out/etc
  71
  72     installManPage docs/*.[1-9]
  73     runHook postInstall
  74   '';
  75
  76   passthru.tests = { inherit (nixosTests) cri-o; };
  77
  78   meta = with lib; {
  79     homepage = "https://cri-o.io";
  80     description = ''
  81       Open Container Initiative-based implementation of the
  82       Kubernetes Container Runtime Interface
  83     '';
  84     license = licenses.asl20;
  85     maintainers = with maintainers; [ ] ++ teams.podman.members;
  86     platforms = platforms.linux;
  87   };
  88 }