pkgs/applications/virtualization/lima/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   buildGoModule,
   5   fetchFromGitHub,
   6   installShellFiles,
   7   qemu,
   8   sigtool,
   9   makeWrapper,
  10   nix-update-script,
  11   apple-sdk_15,
  12   lima,
  13 }:
  14
  15 buildGoModule rec {
  16   pname = "lima";
  17   version = "1.0.2";
  18
  19   src = fetchFromGitHub {
  20     owner = "lima-vm";
  21     repo = "lima";
  22     rev = "v${version}";
  23     hash = "sha256-LNsxMrbEgdosGDDUNvMZq/hpP5azNiIHjKTp0Iw/PC0=";
  24   };
  25
  26   vendorHash = "sha256-taozyQBJvkCsJAaOHg1gFK4qOnepRbzIn4jHzxfAn6A=";
  27
  28   nativeBuildInputs = [
  29     makeWrapper
  30     installShellFiles
  31   ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ sigtool ];
  32
  33   buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [ apple-sdk_15 ];
  34
  35   postPatch = ''
  36     substituteInPlace Makefile \
  37       --replace-fail 'codesign -f -v --entitlements vz.entitlements -s -' 'codesign -f --entitlements vz.entitlements -s -'
  38   '';
  39
  40   # It attaches entitlements with codesign and strip removes those,
  41   # voiding the entitlements and making it non-operational.
  42   dontStrip = stdenv.hostPlatform.isDarwin;
  43
  44   buildPhase = ''
  45     runHook preBuild
  46     make "VERSION=v${version}" "CC=${stdenv.cc.targetPrefix}cc" binaries
  47     runHook postBuild
  48   '';
  49
  50   preCheck = ''
  51     # Workaround for: could not create "/homeless-shelter/.lima/_config" directory: mkdir /homeless-shelter: permission denied
  52     export LIMA_HOME="$(mktemp -d)"
  53   '';
  54
  55   installPhase =
  56     ''
  57       runHook preInstall
  58       mkdir -p $out
  59       cp -r _output/* $out
  60       wrapProgram $out/bin/limactl \
  61         --prefix PATH : ${lib.makeBinPath [ qemu ]}
  62     ''
  63     + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
  64       installShellCompletion --cmd limactl \
  65         --bash <($out/bin/limactl completion bash) \
  66         --fish <($out/bin/limactl completion fish) \
  67         --zsh <($out/bin/limactl completion zsh)
  68     ''
  69     + ''
  70       runHook postInstall
  71     '';
  72
  73   doInstallCheck = true;
  74   # Workaround for: "panic: $HOME is not defined" at https://github.com/lima-vm/lima/blob/v1.0.2/pkg/limayaml/defaults.go#L52
  75   # Don't use versionCheckHook for this package. It cannot inject environment variables.
  76   installCheckPhase = ''
  77     if [[ "$(HOME="$(mktemp -d)" "$out/bin/limactl" --version | cut -d ' ' -f 3)" == "${version}" ]]; then
  78       echo '${pname} smoke check passed'
  79     else
  80       echo '${pname} smoke check failed'
  81       return 1
  82     fi
  83     USER=nix $out/bin/limactl validate templates/default.yaml
  84   '';
  85
  86   passthru.updateScript = nix-update-script { };
  87
  88   meta = with lib; {
  89     homepage = "https://github.com/lima-vm/lima";
  90     description = "Linux virtual machines (on macOS, in most cases)";
  91     changelog = "https://github.com/lima-vm/lima/releases/tag/v${version}";
  92     license = licenses.asl20;
  93     maintainers = with maintainers; [ anhduy ];
  94   };
  95 }