pkgs/by-name/ap/appstream-glib/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   substituteAll,
   6   docbook_xml_dtd_42,
   7   docbook_xsl,
   8   fontconfig,
   9   freetype,
  10   gdk-pixbuf,
  11   gettext,
  12   glib,
  13   gobject-introspection,
  14   gperf,
  15   gtk-doc,
  16   gtk3,
  17   json-glib,
  18   libarchive,
  19   curl,
  20   libuuid,
  21   libxslt,
  22   meson,
  23   ninja,
  24   pkg-config,
  25   pngquant,
  26 }:
  27 stdenv.mkDerivation rec {
  28   pname = "appstream-glib";
  29   version = "0.8.2";
  30
  31   outputs = [
  32     "out"
  33     "dev"
  34     "man"
  35     "installedTests"
  36   ];
  37   outputBin = "dev";
  38
  39   src = fetchFromGitHub {
  40     owner = "hughsie";
  41     repo = "appstream-glib";
  42     rev = "${lib.replaceStrings [ "-" ] [ "_" ] pname}_${lib.replaceStrings [ "." ] [ "_" ] version}";
  43     sha256 = "sha256-3QFiOJ38talA0GGL++n+DaA/AN7l4LOZQ7BJV6o8ius=";
  44   };
  45
  46   nativeBuildInputs = [
  47     docbook_xml_dtd_42
  48     docbook_xsl
  49     gettext
  50     gobject-introspection
  51     gperf
  52     gtk-doc
  53     libxslt
  54     meson
  55     ninja
  56     pkg-config
  57   ];
  58
  59   buildInputs = [
  60     fontconfig
  61     freetype
  62     gdk-pixbuf
  63     glib
  64     gtk3
  65     json-glib
  66     libarchive
  67     curl
  68     libuuid
  69   ];
  70
  71   propagatedBuildInputs = [
  72     glib
  73     gdk-pixbuf
  74   ];
  75
  76   patches = [
  77     (substituteAll {
  78       src = ./paths.patch;
  79       pngquant = "${pngquant}/bin/pngquant";
  80     })
  81   ];
  82
  83   mesonFlags = [
  84     "-Drpm=false"
  85     "-Dstemmer=false"
  86     "-Ddep11=false"
  87   ];
  88
  89   doCheck = false; # fails at least 1 test
  90
  91   postInstall = ''
  92     moveToOutput "share/installed-tests" "$installedTests"
  93   '';
  94
  95   meta = with lib; {
  96     description = "Objects and helper methods to read and write AppStream metadata";
  97     homepage = "https://people.freedesktop.org/~hughsient/appstream-glib/";
  98     license = licenses.lgpl2Plus;
  99     platforms = platforms.unix;
 100     maintainers = with maintainers; [ matthewbauer ];
 101   };
 102 }