pkgs/by-name/au/autotools-language-server/package.nix

   1 {
   2   lib,
   3   python311,
   4   fetchFromGitHub,
   5   fetchpatch,
   6 }:
   7
   8 let
   9   python3 = python311.override {
  10     self = python3;
  11     packageOverrides = _: super: {
  12       tree-sitter = super.tree-sitter_0_21;
  13       lsp-tree-sitter = super.lsp-tree-sitter.overridePythonAttrs (__: {
  14         pythonRelaxDeps = [ "tree-sitter" ];
  15       });
  16     };
  17   };
  18 in
  19 python3.pkgs.buildPythonApplication rec {
  20   pname = "autotools-language-server";
  21   version = "0.0.19";
  22   pyproject = true;
  23
  24   src = fetchFromGitHub {
  25     owner = "Freed-Wu";
  26     repo = "autotools-language-server";
  27     rev = "refs/tags/${version}";
  28     hash = "sha256-V0EOV1ZmeC+4svc2fqV6AIiL37dkrxUJAnjywMZcENw=";
  29   };
  30   patches = [
  31     # Right before the release, upstream decided to replace the
  32     # tree-sitter-languages dependency with tree-sitter-make, which is yanked
  33     # from some reason. Hopefully upstream will fix this dependency a bit
  34     # better in the next release. See also:
  35     # https://github.com/Freed-Wu/autotools-language-server/commit/f149843becfcfd6b2bb4a98eb1f3984c01d5fd33#r142659163
  36     (fetchpatch {
  37       url = "https://github.com/Freed-Wu/autotools-language-server/commit/f149843becfcfd6b2bb4a98eb1f3984c01d5fd33.patch";
  38       hash = "sha256-TrzHbfR6GYAEqDIFiCqSX2+Qv4JeFJ5faiKJhNYojf0=";
  39       revert = true;
  40     })
  41   ];
  42
  43   build-system = [
  44     python3.pkgs.setuptools-generate
  45     python3.pkgs.setuptools-scm
  46   ];
  47
  48   dependencies = with python3.pkgs; [
  49     tree-sitter-languages
  50     lsp-tree-sitter
  51   ];
  52   nativeCheckInputs = [
  53     python3.pkgs.pytestCheckHook
  54   ];
  55
  56   meta = with lib; {
  57     description = "Autotools language server, support configure.ac, Makefile.am, Makefile";
  58     homepage = "https://github.com/Freed-Wu/autotools-language-server";
  59     license = licenses.gpl3Only;
  60     maintainers = with maintainers; [ doronbehar ];
  61     mainProgram = "autotools-language-server";
  62   };
  63 }