pkgs/by-name/aw/aws-encryption-sdk-cli/package.nix

   1 {
   2   lib,
   3   aws-encryption-sdk-cli,
   4   fetchPypi,
   5   nix-update-script,
   6   python3,
   7   testers,
   8 }:
   9
  10 let
  11   localPython = python3.override {
  12     self = localPython;
  13     packageOverrides = final: prev: {
  14       urllib3 = prev.urllib3.overridePythonAttrs (prev: rec {
  15         pyproject = true;
  16         version = "1.26.18";
  17         nativeBuildInputs = with final; [ setuptools ];
  18         src = prev.src.override {
  19           inherit version;
  20           hash = "sha256-+OzBu6VmdBNFfFKauVW/jGe0XbeZ0VkGYmFxnjKFgKA=";
  21         };
  22       });
  23     };
  24   };
  25 in
  26
  27 localPython.pkgs.buildPythonApplication rec {
  28   pname = "aws-encryption-sdk-cli";
  29   version = "4.2.0";
  30   pyproject = true;
  31
  32   src = fetchPypi {
  33     inherit pname version;
  34     hash = "sha256-gORrscY+Bgmz2FrKdSBd56jP0yuEklytMeA3wr8tTZU=";
  35   };
  36
  37   build-system = with localPython.pkgs; [
  38     setuptools
  39   ];
  40
  41   dependencies = with localPython.pkgs; [
  42     attrs
  43     aws-encryption-sdk
  44     base64io
  45     setuptools # for pkg_resources
  46     urllib3
  47   ];
  48
  49   doCheck = true;
  50
  51   nativeCheckInputs = with localPython.pkgs; [
  52     mock
  53     pytest-mock
  54     pytest7CheckHook
  55   ];
  56
  57   disabledTestPaths = [
  58     # requires networking
  59     "test/integration"
  60   ];
  61
  62   # Upstream did not adapt to pytest 8 yet.
  63   pytestFlagsArray = [
  64     "-W"
  65     "ignore::pytest.PytestRemovedIn8Warning"
  66   ];
  67
  68   passthru = {
  69     updateScript = nix-update-script { };
  70     tests.version = testers.testVersion {
  71       package = aws-encryption-sdk-cli;
  72       command = "aws-encryption-cli --version";
  73     };
  74   };
  75
  76   meta = with lib; {
  77     homepage = "https://aws-encryption-sdk-cli.readthedocs.io/";
  78     changelog = "https://github.com/aws/aws-encryption-sdk-cli/blob/v${version}/CHANGELOG.rst";
  79     description = "CLI wrapper around aws-encryption-sdk-python";
  80     license = licenses.asl20;
  81     mainProgram = "aws-encryption-cli";
  82     maintainers = with maintainers; [ anthonyroussel ];
  83   };
  84 }