pkgs/by-name/be/bento4/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6 }:
   7 stdenv.mkDerivation rec {
   8   pname = "bento4";
   9   version = "1.6.0-641";
  10
  11   src = fetchFromGitHub {
  12     owner = "axiomatic-systems";
  13     repo = "Bento4";
  14     rev = "v${version}";
  15     hash = "sha256-Qy8D3cbCVHmLAaXtiF64rL2oRurXNCtd5Dsgt0W7WdY=";
  16   };
  17
  18   patches = [
  19     ./libap4.patch # include all libraries as shared, not static
  20   ];
  21
  22   nativeBuildInputs = [ cmake ];
  23
  24   cmakeFlags =
  25     [
  26       "-DBUILD_SHARED_LIBS=ON"
  27     ]
  28     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  29       "-DCMAKE_OSX_ARCHITECTURES="
  30     ];
  31
  32   installPhase = ''
  33     runHook preInstall
  34     mkdir -p $out/{lib,bin}
  35     find -iname '*${stdenv.hostPlatform.extensions.sharedLibrary}' -exec mv --target-directory="$out/lib" {} \;
  36     find -maxdepth 1 -executable -type f -exec mv --target-directory="$out/bin" {} \;
  37     runHook postInstall
  38   '';
  39
  40   # Patch binaries to use our dylib
  41   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  42     find $out/bin -maxdepth 1 -executable -type f -exec install_name_tool -change @rpath/libap4.dylib $out/lib/libap4.dylib {} \;
  43   '';
  44
  45   meta = with lib; {
  46     description = "Full-featured MP4 format and MPEG DASH library and tools";
  47     homepage = "http://bento4.com";
  48     license = licenses.gpl2Plus;
  49     maintainers = with maintainers; [ makefu ];
  50     platforms = platforms.unix;
  51   };
  52 }