pkgs/by-name/bo/boehmgc/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   autoreconfHook,
   6   # doc: https://github.com/ivmai/bdwgc/blob/v8.2.8/doc/README.macros (LARGE_CONFIG)
   7   enableLargeConfig ? false,
   8   enableMmap ? true,
   9   enableStatic ? false,
  10   nixVersions,
  11 }:
  12
  13 stdenv.mkDerivation (finalAttrs: {
  14   pname = "boehm-gc";
  15   version = "8.2.8";
  16
  17   src = fetchFromGitHub {
  18     owner = "ivmai";
  19     repo = "bdwgc";
  20     rev = "v${finalAttrs.version}";
  21     hash = "sha256-UQSLK/05uPal6/m+HMz0QwXVII1leonlmtSZsXjJ+/c=";
  22   };
  23
  24   outputs = [
  25     "out"
  26     "dev"
  27     "doc"
  28   ];
  29   separateDebugInfo = stdenv.hostPlatform.isLinux && stdenv.hostPlatform.libc != "musl";
  30
  31   nativeBuildInputs = [
  32     autoreconfHook
  33   ];
  34
  35   configureFlags =
  36     [
  37       "--enable-cplusplus"
  38       "--with-libatomic-ops=none"
  39     ]
  40     ++ lib.optional enableStatic "--enable-static"
  41     ++ lib.optional enableMmap "--enable-mmap"
  42     ++ lib.optional enableLargeConfig "--enable-large-config";
  43
  44   # This stanza can be dropped when a release fixes this issue:
  45   #   https://github.com/ivmai/bdwgc/issues/376
  46   # The version is checked with == instead of versionAtLeast so we
  47   # don't forget to disable the fix (and if the next release does
  48   # not fix the problem the test failure will be a reminder to
  49   # extend the set of versions requiring the workaround).
  50   makeFlags = lib.optionals (stdenv.hostPlatform.isPower64 && finalAttrs.version == "8.2.8") [
  51     # do not use /proc primitives to track dirty bits; see:
  52     # https://github.com/ivmai/bdwgc/issues/479#issuecomment-1279687537
  53     # https://github.com/ivmai/bdwgc/blob/54522af853de28f45195044dadfd795c4e5942aa/include/private/gcconfig.h#L741
  54     "CFLAGS_EXTRA=-DNO_SOFT_VDB"
  55   ];
  56
  57   # `gctest` fails under x86_64 emulation on aarch64-darwin
  58   # and also on aarch64-linux (qemu-user)
  59   doCheck =
  60     !(
  61       (stdenv.hostPlatform.isDarwin && stdenv.hostPlatform.isx86_64)
  62       || (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64)
  63     );
  64
  65   enableParallelBuilding = true;
  66
  67   passthru.tests = nixVersions;
  68
  69   meta = {
  70     homepage = "https://hboehm.info/gc/";
  71     description = "Boehm-Demers-Weiser conservative garbage collector for C and C++";
  72     longDescription = ''
  73       The Boehm-Demers-Weiser conservative garbage collector can be used as a
  74       garbage collecting replacement for C malloc or C++ new.  It allows you
  75       to allocate memory basically as you normally would, without explicitly
  76       deallocating memory that is no longer useful.  The collector
  77       automatically recycles memory when it determines that it can no longer
  78       be otherwise accessed.
  79
  80       The collector is also used by a number of programming language
  81       implementations that either use C as intermediate code, want to
  82       facilitate easier interoperation with C libraries, or just prefer the
  83       simple collector interface.
  84
  85       Alternatively, the garbage collector may be used as a leak detector for
  86       C or C++ programs, though that is not its primary goal.
  87     '';
  88     changelog = "https://github.com/ivmai/bdwgc/blob/v${finalAttrs.version}/ChangeLog";
  89     license = "https://hboehm.info/gc/license.txt"; # non-copyleft, X11-style license
  90     maintainers = with lib.maintainers; [ ];
  91     platforms = lib.platforms.all;
  92   };
  93 })