pkgs/by-name/ga/gancio/plugin-telegram-bridge/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitLab,
   5   fetchYarnDeps,
   6   yarnConfigHook,
   7   yarnInstallHook,
   8   nodejs,
   9   nix-update-script,
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "gancio-plugin-telegram-bridge";
  14   version = "1.0.5";
  15
  16   src = fetchFromGitLab {
  17     domain = "framagit.org";
  18     owner = "bcn.convocala";
  19     repo = "gancio-plugin-telegram-bridge";
  20     rev = "v${version}";
  21     hash = "sha256-URiyV7bl8t25NlVJM/gEqPB67TZ4vQdfu4mvHITteSQ=";
  22   };
  23
  24   # upstream doesn't provide a yarn.lock file
  25   postPatch = ''
  26     cp --no-preserve=all ${./yarn.lock} ./yarn.lock
  27   '';
  28
  29   offlineCache = fetchYarnDeps {
  30     yarnLock = ./yarn.lock;
  31     hash = "sha256-BcRVmVA5pnFzpg2gN/nKLzENnoEdwrE0EgulDizq8Ok=";
  32   };
  33
  34   nativeBuildInputs = [
  35     yarnConfigHook
  36     yarnInstallHook
  37     nodejs
  38   ];
  39
  40   postInstall = ''
  41     ln -s "$out/lib/node_modules/gancio-plugin-telegram/index.js" "$out/index.js"
  42     ln -s "$out/lib/node_modules/gancio-plugin-telegram/node_modules" "$out/node_modules"
  43   '';
  44
  45   passthru = {
  46     inherit nodejs;
  47     updateScript = nix-update-script { };
  48   };
  49
  50   meta = {
  51     description = "Telegram bridge for Gancio, republishes content to Telegram channels or groups";
  52     homepage = "https://framagit.org/bcn.convocala/gancio-plugin-telegram-bridge";
  53     license = lib.licenses.agpl3Plus;
  54     platforms = lib.platforms.linux;
  55     maintainers = with lib.maintainers; [ jbgi ];
  56   };
  57 }