pkgs/by-name/ls/lsof/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   buildPackages,
   6   perl,
   7   which,
   8   ncurses,
   9   nukeReferences,
  10   freebsd,
  11   ed,
  12 }:
  13
  14 let
  15   dialect = lib.last (lib.splitString "-" stdenv.hostPlatform.system);
  16 in
  17
  18 stdenv.mkDerivation rec {
  19   pname = "lsof";
  20   version = "4.99.4";
  21
  22   src = fetchFromGitHub {
  23     owner = "lsof-org";
  24     repo = "lsof";
  25     rev = version;
  26     hash = "sha256-JyvQV/JOMaL/3jUr6O0YIzJU/JcXVR65CJf5ip7334w=";
  27   };
  28
  29   postPatch =
  30     ''
  31       patchShebangs --build lib/dialects/*/Mksrc
  32       # Do not re-build version.h in every 'make' to allow nuke-refs below.
  33       # We remove phony 'FRC' target that forces rebuilds:
  34       #   'version.h: FRC ...' is translated to 'version.h: ...'.
  35       sed -i lib/dialects/*/Makefile -e 's/version.h:\s*FRC/version.h:/'
  36     ''
  37     # help Configure find libproc.h in $SDKROOT
  38     + lib.optionalString stdenv.hostPlatform.isDarwin ''
  39       sed -i -e 's|lcurses|lncurses|g' \
  40              -e "s|/Library.*/MacOSX.sdk/|\"$SDKROOT\"/|" Configure
  41     '';
  42
  43   depsBuildBuild = [ buildPackages.stdenv.cc ];
  44   nativeBuildInputs = [
  45     nukeReferences
  46     perl
  47     which
  48     ed
  49   ];
  50   buildInputs = [ ncurses ];
  51
  52   # Stop build scripts from searching global include paths
  53   LSOF_INCLUDE = "${lib.getDev stdenv.cc.libc}/include";
  54   configurePhase =
  55     let
  56       genericFlags = "LSOF_CC=$CC LSOF_AR=\"$AR cr\" LSOF_RANLIB=$RANLIB";
  57       linuxFlags = lib.optionalString stdenv.hostPlatform.isLinux "LINUX_CONF_CC=$CC_FOR_BUILD";
  58       freebsdFlags = lib.optionalString stdenv.hostPlatform.isFreeBSD "FREEBSD_SYS=${freebsd.sys.src}/sys";
  59     in
  60     "${genericFlags} ${linuxFlags} ${freebsdFlags} ./Configure -n ${dialect}";
  61
  62   preBuild = ''
  63     for filepath in $(find dialects/${dialect} -type f); do
  64       sed -i "s,/usr/include,$LSOF_INCLUDE,g" $filepath
  65     done
  66
  67     # Wipe out development-only flags from CFLAGS embedding
  68     make version.h
  69     nuke-refs version.h
  70   '';
  71
  72   installPhase = ''
  73     # Fix references from man page https://github.com/lsof-org/lsof/issues/66
  74     substituteInPlace Lsof.8 \
  75       --replace ".so ./00DIALECTS" "" \
  76       --replace ".so ./version" ".ds VN ${version}"
  77     mkdir -p $out/bin $out/man/man8
  78     cp Lsof.8 $out/man/man8/lsof.8
  79     cp lsof $out/bin
  80   '';
  81
  82   meta = {
  83     homepage = "https://github.com/lsof-org/lsof";
  84     description = "Tool to list open files";
  85     mainProgram = "lsof";
  86     longDescription = ''
  87       List open files. Can show what process has opened some file,
  88       socket (IPv6/IPv4/UNIX local), or partition (by opening a file
  89       from it).
  90     '';
  91     license = lib.licenses.purdueBsd;
  92     maintainers = with lib.maintainers; [ dezgeg ];
  93     platforms = lib.platforms.unix;
  94   };
  95 }