pkgs/by-name/pd/pdf4qt/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   lcms,
   6   cmake,
   7   pkg-config,
   8   qt6,
   9   wrapGAppsHook3,
  10   openjpeg,
  11   tbb_2021_11,
  12   blend2d,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "pdf4qt";
  17   version = "1.4.0.0";
  18
  19   src = fetchFromGitHub {
  20     owner = "JakubMelka";
  21     repo = "PDF4QT";
  22     rev = "v${finalAttrs.version}";
  23     hash = "sha256-NlIy/C4uHRG5wwXPuqCShe113qhhsQ5jp50zrOLLA2c=";
  24   };
  25
  26   patches = [
  27     # lcms2 cmake module only appears when built with vcpkg.
  28     # We directly search for the corresponding libraries and
  29     # header files instead.
  30     ./find_lcms2_path.patch
  31   ];
  32
  33   nativeBuildInputs = [
  34     cmake
  35     pkg-config
  36     qt6.qttools
  37     qt6.wrapQtAppsHook
  38     # GLib-GIO-ERROR: No GSettings schemas are installed on the system
  39     wrapGAppsHook3
  40   ];
  41
  42   buildInputs = [
  43     qt6.qtbase
  44     qt6.qtwayland
  45     qt6.qtsvg
  46     qt6.qtspeech
  47     lcms
  48     openjpeg
  49     tbb_2021_11
  50     blend2d
  51   ];
  52
  53   cmakeFlags = [
  54     (lib.cmakeBool "PDF4QT_INSTALL_TO_USR" false)
  55   ];
  56
  57   dontWrapGApps = true;
  58
  59   preFixup = ''
  60     qtWrapperArgs+=(''${gappsWrapperArgs[@]})
  61   '';
  62
  63   meta = {
  64     description = "Open source PDF editor";
  65     longDescription = ''
  66       This software is consisting of PDF rendering library,
  67       and several applications, such as advanced document
  68       viewer, command line tool, and document page
  69       manipulator application. Software is implementing PDF
  70       functionality based on PDF Reference 2.0.
  71     '';
  72     homepage = "https://jakubmelka.github.io";
  73     license = lib.licenses.lgpl3Only;
  74     mainProgram = "Pdf4QtViewerLite";
  75     maintainers = with lib.maintainers; [ aleksana ];
  76     platforms = lib.platforms.linux;
  77   };
  78 })