pkgs/by-name/sa/sameboy/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   gtk3,
   6   rgbds,
   7   SDL2,
   8   wrapGAppsHook3,
   9   glib,
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "sameboy";
  14   version = "0.16.7";
  15
  16   src = fetchFromGitHub {
  17     owner = "LIJI32";
  18     repo = "SameBoy";
  19     rev = "v${version}";
  20     sha256 = "sha256-KUvhmORI3hIJFMCW8U2BZYnIwzg7h+GZZA4+U0IPS9E=";
  21   };
  22
  23   enableParallelBuilding = true;
  24   # glib and wrapGAppsHook3 are needed to make the Open ROM menu work.
  25   nativeBuildInputs = [
  26     rgbds
  27     glib
  28     wrapGAppsHook3
  29   ];
  30   buildInputs = [ SDL2 ];
  31
  32   makeFlags = [
  33     "CONF=release"
  34     "FREEDESKTOP=true"
  35     "PREFIX=$(out)"
  36   ];
  37
  38   postPatch = ''
  39     substituteInPlace OpenDialog/gtk.c \
  40       --replace '"libgtk-3.so"' '"${gtk3}/lib/libgtk-3.so"'
  41   '';
  42
  43   meta = with lib; {
  44     homepage = "https://sameboy.github.io";
  45     description = "Game Boy, Game Boy Color, and Super Game Boy emulator";
  46     mainProgram = "sameboy";
  47
  48     longDescription = ''
  49       SameBoy is a user friendly Game Boy, Game Boy Color and Super
  50       Game Boy emulator for macOS, Windows and Unix-like platforms.
  51       SameBoy is extremely accurate and includes a wide range of
  52       powerful debugging features, making it ideal for both casual
  53       players and developers. In addition to accuracy and developer
  54       capabilities, SameBoy has all the features one would expect from
  55       an emulator – from save states to scaling filters.
  56     '';
  57
  58     license = licenses.mit;
  59     maintainers = with maintainers; [ NieDzejkob ];
  60     platforms = platforms.linux;
  61   };
  62 }