pkgs/by-name/sc/scite/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   pkg-config,
   6   wrapGAppsHook3,
   7 }:
   8
   9 stdenv.mkDerivation (finalAttrs: {
  10   pname = "scite";
  11   version = "5.5.3";
  12
  13   src = fetchurl {
  14     url = "https://www.scintilla.org/scite${lib.replaceStrings [ "." ] [ "" ] finalAttrs.version}.tgz";
  15     hash = "sha256-MtXy8a4MzdJP8Rf6otc+Zu+KfYSJnmmXfBS8RVBBbOY=";
  16   };
  17
  18   nativeBuildInputs = [
  19     pkg-config
  20     wrapGAppsHook3
  21   ];
  22
  23   sourceRoot = "scite/gtk";
  24
  25   makeFlags = [
  26     "GTK3=1"
  27     "prefix=${placeholder "out"}"
  28   ];
  29
  30   CXXFLAGS = [
  31     # GCC 13: error: 'intptr_t' does not name a type
  32     "-include cstdint"
  33     "-include system_error"
  34   ];
  35
  36   preBuild = ''
  37     pushd ../../scintilla/gtk
  38     make ''${makeFlags[@]}
  39     popd
  40
  41     pushd ../../lexilla/src
  42     make ''${makeFlags[@]}
  43     popd
  44   '';
  45
  46   enableParallelBuilding = true;
  47
  48   meta = {
  49     homepage = "https://www.scintilla.org/SciTE.html";
  50     description = "SCIntilla based Text Editor";
  51     license = lib.licenses.mit;
  52     platforms = lib.platforms.linux;
  53     maintainers = with lib.maintainers; [
  54       rszibele
  55       aleksana
  56     ];
  57     mainProgram = "SciTE";
  58   };
  59 })