pkgs/by-name/th/themix-gui/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   sassc,
   5   gdk-pixbuf,
   6   glib,
   7   gobject-introspection,
   8   librsvg,
   9   gtk3,
  10   python3,
  11   fetchFromGitHub,
  12   wrapGAppsHook3,
  13 }:
  14
  15 let
  16   py = python3.withPackages (p: [
  17     p.pygobject3
  18   ]);
  19   pname = "themix-gui";
  20   version = "1.15.1";
  21 in
  22 stdenv.mkDerivation {
  23   inherit pname version;
  24
  25   src = fetchFromGitHub {
  26     owner = "themix-project";
  27     repo = "themix-gui";
  28     rev = version;
  29     hash = "sha256-xFtwNx1c7Atb+9yorZhs/uVkkoxbZiELJ0SZ88L7KMs=";
  30     fetchSubmodules = true;
  31   };
  32
  33   nativeBuildInputs = [
  34     gobject-introspection
  35     py
  36     sassc
  37     wrapGAppsHook3
  38   ];
  39
  40   buildInputs = [
  41     gdk-pixbuf
  42     glib
  43     gtk3
  44     librsvg
  45     py
  46   ];
  47
  48   postPatch = ''
  49     substituteInPlace gui.sh packaging/bin/{oomox,themix}-gui --replace python3 ${lib.getExe py}
  50   '';
  51
  52   dontBuild = true;
  53
  54   installPhase = ''
  55     runHook preInstall
  56
  57     make DESTDIR=/ APPDIR=$out/opt/oomox PREFIX=$out install_gui install_import_xresources install_export_xresources
  58     python -O -m compileall $out/opt/oomox/oomox_gui -d /opt/oomox/oomox_gui
  59
  60     runHook postInstall
  61   '';
  62
  63   meta = {
  64     description = "Graphical application for designing themes and exporting them using plugins";
  65     longDescription = ''
  66       Graphical application for generating different color variations of
  67       Oomox (Numix-based) and Materia (ex-Flat-Plat) themes (GTK2, GTK3,
  68       Cinnamon, GNOME, Openbox, Xfwm), Archdroid, Gnome-Color, Numix, Papirus
  69       and Suru++ icon themes. Have a hack for HiDPI in gtk2. Its Base16 plugin
  70       also allowing a lot of app themes support like Alacritty, Emacs, GTK4,
  71       KDE, VIM and many more.
  72     '';
  73     homepage = "https://github.com/themix-project/themix-gui";
  74     license = lib.licenses.gpl3Only;
  75     mainProgram = "themix-gui";
  76     maintainers = [ ];
  77     platforms = lib.platforms.linux;
  78   };
  79 }