pkgs/by-name/wa/waycheck/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitLab,
   5   meson,
   6   ninja,
   7   pkg-config,
   8   qt6,
   9   wayland,
  10   glib,
  11   wrapGAppsHook3,
  12   nix-update-script,
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "waycheck";
  17   version = "1.4.0";
  18
  19   src = fetchFromGitLab {
  20     domain = "gitlab.freedesktop.org";
  21     owner = "serebit";
  22     repo = "waycheck";
  23     rev = "v${finalAttrs.version}";
  24     hash = "sha256-wawz7QCzpeQgdxwFQaZ/yV//AepEE+FLNG7ho/lHtFE=";
  25   };
  26
  27   nativeBuildInputs = [
  28     meson
  29     ninja
  30     pkg-config
  31     wrapGAppsHook3
  32     qt6.wrapQtAppsHook
  33   ];
  34
  35   buildInputs = [
  36     glib
  37     wayland
  38     qt6.qtwayland
  39   ];
  40
  41   dontWrapGApps = true;
  42
  43   postPatch = ''
  44     substituteInPlace scripts/mesonPostInstall.sh \
  45       --replace-fail "#!/usr/bin/env sh" "#!${stdenv.shell}" \
  46       --replace-fail "update-desktop-database -q" "update-desktop-database $out/share/applications"
  47   '';
  48
  49   preFixup = ''
  50     qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
  51   '';
  52
  53   passthru.updateScript = nix-update-script { };
  54
  55   meta = {
  56     description = "Simple GUI that displays the protocols implemented by a Wayland compositor";
  57     homepage = "https://gitlab.freedesktop.org/serebit/waycheck";
  58     license = lib.licenses.asl20;
  59     maintainers = with lib.maintainers; [
  60       julienmalka
  61       pandapip1
  62     ];
  63     mainProgram = "waycheck";
  64     platforms = lib.platforms.linux;
  65   };
  66 })