pkgs/desktops/xfce/applications/catfish/default.nix

   1 {
   2   lib,
   3   fetchFromGitLab,
   4   gitUpdater,
   5   file,
   6   which,
   7   intltool,
   8   gobject-introspection,
   9   findutils,
  10   xdg-utils,
  11   dconf,
  12   gtk3,
  13   python3Packages,
  14   xfconf,
  15   wrapGAppsHook3,
  16 }:
  17
  18 python3Packages.buildPythonApplication rec {
  19   pname = "catfish";
  20   version = "4.18.0";
  21
  22   src = fetchFromGitLab {
  23     domain = "gitlab.xfce.org";
  24     owner = "apps";
  25     repo = pname;
  26     rev = "${pname}-${version}";
  27     sha256 = "sha256-hfbIgSFn48++eGrJXzhXRxhWkrjgTYsr7BX/n0EXhGo=";
  28   };
  29
  30   nativeBuildInputs = [
  31     python3Packages.distutils-extra
  32     file
  33     which
  34     intltool
  35     gobject-introspection # for setup hook populating GI_TYPELIB_PATH
  36     wrapGAppsHook3
  37   ];
  38
  39   buildInputs = [
  40     gtk3
  41     dconf
  42     python3Packages.pyxdg
  43     python3Packages.ptyprocess
  44     python3Packages.pycairo
  45   ];
  46
  47   propagatedBuildInputs = [
  48     python3Packages.dbus-python
  49     python3Packages.pygobject3
  50     python3Packages.pexpect
  51     xdg-utils
  52     findutils
  53     xfconf
  54   ];
  55
  56   # Explicitly set the prefix dir in "setup.py" because setuptools is
  57   # not using "$out" as the prefix when installing catfish data. In
  58   # particular the variable "__catfish_data_directory__" in
  59   # "catfishconfig.py" is being set to a subdirectory in the python
  60   # path in the store.
  61   postPatch = ''
  62     sed -i "/^        if self.root/i\\        self.prefix = \"$out\"" setup.py
  63   '';
  64
  65   # Disable check because there is no test in the source distribution
  66   doCheck = false;
  67
  68   dontWrapGApps = true;
  69
  70   preFixup = ''
  71     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  72   '';
  73
  74   passthru.updateScript = gitUpdater { rev-prefix = "${pname}-"; };
  75
  76   meta = with lib; {
  77     homepage = "https://docs.xfce.org/apps/catfish/start";
  78     description = "Handy file search tool";
  79     mainProgram = "catfish";
  80     longDescription = ''
  81       Catfish is a handy file searching tool. The interface is
  82       intentionally lightweight and simple, using only GTK 3.
  83       You can configure it to your needs by using several command line
  84       options.
  85     '';
  86     license = licenses.gpl2Plus;
  87     platforms = platforms.linux;
  88     maintainers = with maintainers; [ ] ++ teams.xfce.members;
  89   };
  90 }