pkgs/development/compilers/chicken/5/default.nix

   1 {
   2   lib,
   3   newScope,
   4   fetchurl,
   5 }:
   6
   7 lib.makeScope newScope (self: {
   8
   9   fetchegg =
  10     {
  11       pname,
  12       version,
  13       sha256,
  14       ...
  15     }:
  16     fetchurl {
  17       inherit sha256;
  18       url = "https://code.call-cc.org/egg-tarballs/5/${pname}/${pname}-${version}.tar.gz";
  19     };
  20
  21   eggDerivation = self.callPackage ./eggDerivation.nix { };
  22
  23   chicken = self.callPackage ./chicken.nix {
  24     bootstrap-chicken = self.chicken.override { bootstrap-chicken = null; };
  25   };
  26
  27   chickenEggs = lib.recurseIntoAttrs (
  28     lib.makeScope self.newScope (
  29       eggself:
  30       (lib.mapAttrs (
  31         pname:
  32         eggData@{
  33           version,
  34           synopsis,
  35           dependencies,
  36           license,
  37           ...
  38         }:
  39         self.eggDerivation {
  40           name = "${pname}-${version}";
  41           src = self.fetchegg (eggData // { inherit pname; });
  42           buildInputs = map (x: eggself.${x}) dependencies;
  43           meta.homepage = "https://code.call-cc.org/cgi-bin/gitweb.cgi?p=eggs-5-latest.git;a=tree;f=${pname}/${version}";
  44           meta.description = synopsis;
  45           meta.license =
  46             (
  47               lib.licenses
  48               // {
  49                 "agpl" = lib.licenses.agpl3Only;
  50                 "artistic" = lib.licenses.artistic2;
  51                 "bsd" = lib.licenses.bsd3;
  52                 "bsd-1-clause" = lib.licenses.bsd1;
  53                 "bsd-2-clause" = lib.licenses.bsd2;
  54                 "bsd-3-clause" = lib.licenses.bsd3;
  55                 "gpl" = lib.licenses.gpl3Only;
  56                 "gpl-2" = lib.licenses.gpl2Only;
  57                 "gplv2" = lib.licenses.gpl2Only;
  58                 "gpl-3" = lib.licenses.gpl3Only;
  59                 "gpl-3.0" = lib.licenses.gpl3Only;
  60                 "gplv3" = lib.licenses.gpl3Only;
  61                 "lgpl" = lib.licenses.lgpl3Only;
  62                 "lgpl-2" = lib.licenses.lgpl2Only;
  63                 "lgpl-2.0+" = lib.licenses.lgpl2Plus;
  64                 "lgpl-2.1" = lib.licenses.lgpl21Only;
  65                 "lgpl-2.1-or-later" = lib.licenses.lgpl21Plus;
  66                 "lgpl-3" = lib.licenses.lgpl3Only;
  67                 "lgplv3" = lib.licenses.lgpl3Only;
  68                 "public-domain" = lib.licenses.publicDomain;
  69                 "srfi" = lib.licenses.bsd3;
  70                 "unicode" = lib.licenses.ucd;
  71                 "zlib-acknowledgement" = lib.licenses.zlib;
  72               }
  73             ).${license} or license;
  74         }
  75       ) (lib.importTOML ./deps.toml))
  76     )
  77   );
  78
  79   egg2nix = self.callPackage ./egg2nix.nix { };
  80
  81 })