pkgs/development/coq-modules/compcert/default.nix

   1 {
   2   lib,
   3   mkCoqDerivation,
   4   coq,
   5   flocq,
   6   MenhirLib,
   7   ocamlPackages,
   8   fetchpatch,
   9   makeWrapper,
  10   coq2html,
  11   stdenv,
  12   tools ? stdenv.cc,
  13   version ? null,
  14 }:
  15
  16 let
  17
  18   # https://compcert.org/man/manual002.html
  19   targets = {
  20     x86_64-linux = "x86_64-linux";
  21     aarch64-linux = "aarch64-linux";
  22     x86_64-darwin = "x86_64-macos";
  23     aarch64-darwin = "aarch64-macos";
  24     riscv32-linux = "rv32-linux";
  25     riscv64-linux = "rv64-linux";
  26   };
  27
  28   target =
  29     targets.${stdenv.hostPlatform.system}
  30       or (throw "Unsupported system: ${stdenv.hostPlatform.system}");
  31
  32   compcert = mkCoqDerivation {
  33
  34     pname = "compcert";
  35     owner = "AbsInt";
  36
  37     inherit version;
  38     releaseRev = v: "v${v}";
  39
  40     defaultVersion =
  41       with lib.versions;
  42       lib.switch coq.version [
  43         {
  44           case = range "8.14" "8.20";
  45           out = "3.14";
  46         }
  47         {
  48           case = isEq "8.13";
  49           out = "3.10";
  50         }
  51         {
  52           case = isEq "8.12";
  53           out = "3.9";
  54         }
  55         {
  56           case = range "8.8" "8.11";
  57           out = "3.8";
  58         }
  59       ] null;
  60
  61     release = {
  62       "3.8".sha256 = "1gzlyxvw64ca12qql3wnq3bidcx9ygsklv9grjma3ib4hvg7vnr7";
  63       "3.9".sha256 = "1srcz2dqrvmbvv5cl66r34zqkm0hsbryk7gd3i9xx4slahc9zvdb";
  64       "3.10".sha256 = "sha256:19rmx8r8v46101ij5myfrz60arqjy7q3ra3fb8mxqqi3c8c4l4j6";
  65       "3.11".sha256 = "sha256-ZISs/ZAJVWtxp9+Sg5qV5Rss1gI9hK769GnBfawLa6A=";
  66       "3.12".sha256 = "sha256-hXkQ8UnAx3k50OJGBmSm4hgrnRFCosu4+PEMrcKfmV0=";
  67       "3.13".sha256 = "sha256-ZedxgEPr1ZgKIcyhQ6zD1l2xr6RDNNUYq/4ZyR6ojM4=";
  68       "3.13.1".sha256 = "sha256-ldXbuzVB0Z+UVTd5S4yGSg6oRYiKbXLMmUZcQsJLcns=";
  69       "3.14".sha256 = "sha256-QXJMpp/BaPiK5okHeo2rcmXENToXKjB51UqljMHTDgw=";
  70     };
  71
  72     strictDeps = true;
  73
  74     nativeBuildInputs = with ocamlPackages; [
  75       makeWrapper
  76       ocaml
  77       findlib
  78       menhir
  79       coq
  80       coq2html
  81     ];
  82     buildInputs = with ocamlPackages; [ menhirLib ];
  83     propagatedBuildInputs = [
  84       flocq
  85       MenhirLib
  86     ];
  87
  88     enableParallelBuilding = true;
  89
  90     postPatch = ''
  91       substituteInPlace ./configure \
  92         --replace \$\{toolprefix\}ar 'ar' \
  93         --replace '{toolprefix}gcc' '{toolprefix}cc'
  94     '';
  95
  96     configurePhase = ''
  97       ./configure -clightgen \
  98       -prefix $out \
  99       -coqdevdir $lib/lib/coq/${coq.coq-version}/user-contrib/compcert/ \
 100       -toolprefix ${tools}/bin/ \
 101       -use-external-Flocq \
 102       -use-external-MenhirLib \
 103       ${target} \
 104     ''; # don't remove the \ above, the command gets appended in override below
 105
 106     installTargets = "documentation install";
 107     installFlags = [ ]; # trust ./configure
 108     preInstall = ''
 109       mkdir -p $out/share/man
 110       mkdir -p $man/share
 111     '';
 112     postInstall = ''
 113       # move man into place
 114       mv $out/share/man/ $man/share/
 115
 116       # move docs into place
 117       mkdir -p $doc/share/doc/compcert
 118       mv doc/html $doc/share/doc/compcert/
 119
 120       # wrap ccomp to undefine _FORTIFY_SOURCE; ccomp invokes cc1 which sets
 121       # _FORTIFY_SOURCE=2 by default, but undefines __GNUC__ (as it should),
 122       # which causes a warning in libc. this suppresses it.
 123       for x in ccomp clightgen; do
 124         wrapProgram $out/bin/$x --add-flags "-U_FORTIFY_SOURCE"
 125       done
 126     '';
 127
 128     outputs = [
 129       "out"
 130       "lib"
 131       "doc"
 132       "man"
 133     ];
 134
 135     meta = with lib; {
 136       description = "Formally verified C compiler";
 137       homepage = "https://compcert.org";
 138       license = licenses.inria-compcert;
 139       platforms = builtins.attrNames targets;
 140       maintainers = with maintainers; [
 141         thoughtpolice
 142         jwiegley
 143         vbgl
 144       ];
 145     };
 146   };
 147   patched_compcert = compcert.overrideAttrs (o: {
 148     patches =
 149       with lib.versions;
 150       lib.switch [ coq.version o.version ]
 151         [
 152           {
 153             cases = [
 154               (range "8.12.2" "8.13.2")
 155               "3.8"
 156             ];
 157             out = [
 158               # Support for Coq 8.12.2
 159               (fetchpatch {
 160                 url = "https://github.com/AbsInt/CompCert/commit/06956421b4307054af221c118c5f59593c0e67b9.patch";
 161                 sha256 = "1f90q6j3xfvnf3z830bkd4d8526issvmdlrjlc95bfsqs78i1yrl";
 162               })
 163               # Support for Coq 8.13.0
 164               (fetchpatch {
 165                 url = "https://github.com/AbsInt/CompCert/commit/0895388e7ebf9c9f3176d225107e21968919fb97.patch";
 166                 sha256 = "0qhkzgb2xl5kxys81pldp3mr39gd30lvr2l2wmplij319vp3xavd";
 167               })
 168               # Support for Coq 8.13.1
 169               (fetchpatch {
 170                 url = "https://github.com/AbsInt/CompCert/commit/6bf310dd678285dc193798e89fc2c441d8430892.patch";
 171                 sha256 = "026ahhvpj5pksy90f8pnxgmhgwfqk4kwyvcf8x3dsanvz98d4pj5";
 172               })
 173               # Drop support for Coq < 8.9
 174               (fetchpatch {
 175                 url = "https://github.com/AbsInt/CompCert/commit/7563a5df926a4c6fb1489a7a4c847641c8a35095.patch";
 176                 sha256 = "05vkslzy399r3dm6dmjs722rrajnyfa30xsyy3djl52isvn4gyfb";
 177               })
 178               # Support for Coq 8.13.2
 179               (fetchpatch {
 180                 url = "https://github.com/AbsInt/CompCert/commit/48bc183167c4ce01a5c9ea86e49d60530adf7290.patch";
 181                 sha256 = "0j62lppfk26d1brdp3qwll2wi4gvpx1k70qivpvby5f7dpkrkax1";
 182               })
 183             ];
 184           }
 185           {
 186             cases = [
 187               (range "8.14" "8.15")
 188               "3.10"
 189             ];
 190             out = [
 191               # Support for Coq 8.14.1
 192               (fetchpatch {
 193                 url = "https://github.com/AbsInt/CompCert/commit/a79f0f99831aa0b0742bf7cce459cc9353bd7cd0.patch";
 194                 sha256 = "sha256:0g20x8gfzvplpad9y9vr1p33k6qv6rsp691x6687v9ffvz7zsz94";
 195               })
 196               # Support for Coq 8.15.0
 197               (fetchpatch {
 198                 url = "https://github.com/AbsInt/CompCert/commit/a882f78c069f7337dd9f4abff117d4df98ef38a6.patch";
 199                 sha256 = "sha256:16i87s608fj9ni7cvd5wrd7gicqniad7w78wi26pxdy0pacl7bjg";
 200               })
 201               # Support for Coq 8.15.1
 202               (fetchpatch {
 203                 url = "https://github.com/AbsInt/CompCert/commit/10a976994d7fd30d143354c289ae735d210ccc09.patch";
 204                 sha256 = "sha256:0bg58gpkgxlmxzp6sg0dvybrfk0pxnm7qd6vxlrbsbm2w6wk03jv";
 205               })
 206               # Support for Coq 8.15.2
 207               (fetchpatch {
 208                 url = "https://github.com/AbsInt/CompCert/commit/283a5be7296c4c0a94d863b427c77007ab875733.patch";
 209                 sha256 = "sha256:1s7hvb5ii3p8kkcjlzwldvk8xc3iiibxi9935qjbrh25xi6qs66k";
 210               })
 211             ];
 212           }
 213           {
 214             cases = [
 215               (isEq "8.16")
 216               (range "3.11" "3.12")
 217             ];
 218             out = [
 219               # Support for Coq 8.16.0
 220               (fetchpatch {
 221                 url = "https://github.com/AbsInt/CompCert/commit/34be08a23d18d56f2dde24fd24b6dbe3bcb01ec3.patch";
 222                 sha256 = "sha256-a5YnftGVadVypEqrOYRRxI7YtGOEWyKnO4GqakFhvzI=";
 223               })
 224               # Support for Coq 8.16.1
 225               (fetchpatch {
 226                 url = "https://github.com/AbsInt/CompCert/commit/35531503b3493cb9b0ec8a8585e84928c85b4af9.patch";
 227                 hash = "sha256-DvtYi/eiPUe8tA0EFTcCjJA0JjtVKceUsX4ZDM0pWkE=";
 228               })
 229             ];
 230           }
 231           {
 232             cases = [
 233               (range "8.17" "8.19")
 234               (isEq "3.13")
 235             ];
 236             out = [
 237               # Support for Coq 8.17.0 & Coq 8.17.1
 238               (fetchpatch {
 239                 url = "https://github.com/AbsInt/CompCert/commit/2e04d986bdae578186e40330842878559a550402.patch";
 240                 hash = "sha256-2ZRAjUUSScJI8ogWFTnukCUnJdLWGvyOPyfIVlHL4ig=";
 241               })
 242               # Support for Coq 8.18.0
 243               (fetchpatch {
 244                 url = "https://github.com/AbsInt/CompCert/commit/28218c5663cba36c6078ca342335d4e55c412bd7.patch";
 245                 hash = "sha256-aAatUMO26oZwFYGh1BXYWxbTuyOgU8BAKMGDS5796hM=";
 246               })
 247               # MenhirLib update
 248               (fetchpatch {
 249                 url = "https://github.com/AbsInt/CompCert/commit/9f3d7b6eb99377ad4689cd57563c484c57baa457.patch";
 250                 hash = "sha256-paofdSBxP/JFoBSiO1OI+mjKRI3UCanXRh/drzYt93E=";
 251               })
 252               # Support for Coq 8.19.0 & Coq 8.19.1
 253               (fetchpatch {
 254                 url = "https://github.com/AbsInt/CompCert/commit/a2e4ed62fc558d565366845f9d135bd7db5e23c4.patch";
 255                 hash = "sha256-ufk0bokuayLfkSvK3cK4E9iXU5eZpp9d/ETSa/zCfMg=";
 256               })
 257               # Support for Coq 8.19.2
 258               (fetchpatch {
 259                 url = "https://github.com/AbsInt/CompCert/commit/8fcfb7d2a6e9ba44003ccab0dfcc894982779af1.patch";
 260                 hash = "sha256-m/kcnDBBPWFriipuGvKZUqLQU8/W1uqw8j4qfCwnTZk=";
 261               })
 262             ];
 263           }
 264           {
 265             cases = [
 266               (range "8.19" "8.20")
 267               (isEq "3.14")
 268             ];
 269             out = [
 270               # Support for Coq 8.19.2
 271               (fetchpatch {
 272                 url = "https://github.com/AbsInt/CompCert/commit/8fcfb7d2a6e9ba44003ccab0dfcc894982779af1.patch";
 273                 hash = "sha256-m/kcnDBBPWFriipuGvKZUqLQU8/W1uqw8j4qfCwnTZk=";
 274               })
 275               # Support for Coq 8.20.0
 276               (fetchpatch {
 277                 url = "https://github.com/AbsInt/CompCert/commit/20a5b48758bf8ac18e4c420df67017b371efc237.patch";
 278                 hash = "sha256-TJ87CvLiAv1absGnPsTXsD/HQwKgS82loUTcosulyso=";
 279               })
 280             ];
 281           }
 282         ]
 283         [ ];
 284   });
 285 in
 286 patched_compcert.overrideAttrs (
 287   o:
 288   lib.optionalAttrs (coq.version != null && coq.version == "dev") {
 289     configurePhase = "${o.configurePhase} -ignore-ocaml-version -ignore-coq-version";
 290   }
 291 )