pkgs/development/libraries/gdk-pixbuf/default.nix

   1 {
   2   stdenv,
   3   fetchurl,
   4   nixosTests,
   5   fixDarwinDylibNames,
   6   meson,
   7   ninja,
   8   pkg-config,
   9   gettext,
  10   python3,
  11   docutils,
  12   gi-docgen,
  13   glib,
  14   libtiff,
  15   libjpeg,
  16   libpng,
  17   gnome,
  18   doCheck ? false,
  19   makeWrapper,
  20   lib,
  21   testers,
  22   buildPackages,
  23   withIntrospection ?
  24     lib.meta.availableOn stdenv.hostPlatform gobject-introspection
  25     && stdenv.hostPlatform.emulatorAvailable buildPackages,
  26   gobject-introspection,
  27 }:
  28
  29 stdenv.mkDerivation (finalAttrs: {
  30   pname = "gdk-pixbuf";
  31   version = "2.42.12";
  32
  33   outputs =
  34     [
  35       "out"
  36       "dev"
  37       "man"
  38     ]
  39     ++ lib.optional withIntrospection "devdoc"
  40     ++ lib.optional (stdenv.buildPlatform == stdenv.hostPlatform) "installedTests";
  41
  42   src =
  43     let
  44       inherit (finalAttrs) pname version;
  45     in
  46     fetchurl {
  47       url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  48       hash = "sha256-uVBbNEW5p+SM7TR2DDvLc+lm3zrJTJWhSMtmmrdI48c=";
  49     };
  50
  51   patches = [
  52     # Move installed tests to a separate output
  53     ./installed-tests-path.patch
  54   ];
  55
  56   # gdk-pixbuf-thumbnailer is not wrapped therefore strictDeps will work
  57   strictDeps = true;
  58
  59   depsBuildBuild = [
  60     pkg-config
  61   ];
  62
  63   nativeBuildInputs =
  64     [
  65       meson
  66       ninja
  67       pkg-config
  68       gettext
  69       python3
  70       makeWrapper
  71       glib
  72
  73       # for man pages
  74       docutils
  75     ]
  76     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  77       fixDarwinDylibNames
  78     ]
  79     ++ lib.optionals withIntrospection [
  80       gi-docgen
  81       gobject-introspection
  82     ];
  83
  84   propagatedBuildInputs = [
  85     glib
  86     libtiff
  87     libjpeg
  88     libpng
  89   ];
  90
  91   mesonFlags = [
  92     "-Dgio_sniffing=false"
  93     (lib.mesonBool "gtk_doc" withIntrospection)
  94     (lib.mesonEnable "introspection" withIntrospection)
  95     (lib.mesonEnable "others" true)
  96   ];
  97
  98   postPatch = ''
  99     chmod +x build-aux/* # patchShebangs only applies to executables
 100     patchShebangs build-aux
 101
 102     substituteInPlace tests/meson.build --subst-var-by installedtestsprefix "$installedTests"
 103
 104     # Run-time dependency gi-docgen found: NO (tried pkgconfig and cmake)
 105     # it should be a build-time dep for build
 106     # TODO: send upstream
 107     substituteInPlace docs/meson.build \
 108       --replace "dependency('gi-docgen'," "dependency('gi-docgen', native:true," \
 109       --replace "'gi-docgen', req" "'gi-docgen', native:true, req"
 110
 111     # Remove 'ani' loader until proper fix for CVE-2022-48622
 112     substituteInPlace meson.build --replace-fail "'ani'," ""
 113   '';
 114
 115   postInstall =
 116     ''
 117       # All except one utility seem to be only useful during building.
 118       moveToOutput "bin" "$dev"
 119       moveToOutput "bin/gdk-pixbuf-thumbnailer" "$out"
 120
 121     ''
 122     + lib.optionalString stdenv.hostPlatform.isDarwin ''
 123       # meson erroneously installs loaders with .dylib extension on Darwin.
 124       # Their @rpath has to be replaced before gdk-pixbuf-query-loaders looks at them.
 125       for f in $out/${finalAttrs.passthru.moduleDir}/*.dylib; do
 126           install_name_tool -change @rpath/libgdk_pixbuf-2.0.0.dylib $out/lib/libgdk_pixbuf-2.0.0.dylib $f
 127           mv $f ''${f%.dylib}.so
 128       done
 129     ''
 130     + lib.optionalString withIntrospection ''
 131       # We need to install 'loaders.cache' in lib/gdk-pixbuf-2.0/2.10.0/
 132       ${stdenv.hostPlatform.emulator buildPackages} $dev/bin/gdk-pixbuf-query-loaders --update-cache
 133     '';
 134
 135   # The fixDarwinDylibNames hook doesn't patch binaries.
 136   preFixup = lib.optionalString stdenv.hostPlatform.isDarwin ''
 137     for f in $out/bin/* $dev/bin/*; do
 138         install_name_tool -change @rpath/libgdk_pixbuf-2.0.0.dylib $out/lib/libgdk_pixbuf-2.0.0.dylib $f
 139     done
 140   '';
 141
 142   postFixup = lib.optionalString withIntrospection ''
 143     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
 144     moveToOutput "share/doc" "$devdoc"
 145   '';
 146
 147   # The tests take an excessive amount of time (> 1.5 hours) and memory (> 6 GB).
 148   inherit doCheck;
 149
 150   setupHook = ./setup-hook.sh;
 151
 152   separateDebugInfo = stdenv.hostPlatform.isLinux;
 153
 154   passthru = {
 155     updateScript = gnome.updateScript {
 156       packageName = finalAttrs.pname;
 157       versionPolicy = "odd-unstable";
 158     };
 159
 160     tests = {
 161       installedTests = nixosTests.installed-tests.gdk-pixbuf;
 162       pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
 163     };
 164
 165     # gdk_pixbuf_binarydir and gdk_pixbuf_moduledir variables from gdk-pixbuf-2.0.pc
 166     binaryDir = "lib/gdk-pixbuf-2.0/2.10.0";
 167     moduleDir = "${finalAttrs.passthru.binaryDir}/loaders";
 168   };
 169
 170   meta = with lib; {
 171     description = "Library for image loading and manipulation";
 172     homepage = "https://gitlab.gnome.org/GNOME/gdk-pixbuf";
 173     license = licenses.lgpl21Plus;
 174     maintainers = teams.gnome.members;
 175     mainProgram = "gdk-pixbuf-thumbnailer";
 176     pkgConfigModules = [ "gdk-pixbuf-2.0" ];
 177     platforms = platforms.unix;
 178   };
 179 })