pkgs/development/libraries/libunistring/default.nix

   1 {
   2   fetchurl,
   3   lib,
   4   stdenv,
   5   libiconv,
   6   updateAutotoolsGnuConfigScriptsHook,
   7   darwin,
   8 }:
   9
  10 # Note: this package is used for bootstrapping fetchurl, and thus
  11 # cannot use fetchpatch! All mutable patches (generated by GitHub or
  12 # cgit) that are needed here should be included directly in Nixpkgs as
  13 # files.
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "libunistring";
  17   version = "1.2";
  18
  19   src = fetchurl {
  20     url = "mirror://gnu/libunistring/libunistring-${finalAttrs.version}.tar.gz";
  21     hash = "sha256-/W1WYvpwZIfEg0mnWLV7wUnOlOxsMGJOyf3Ec86rvI4=";
  22   };
  23
  24   outputs = [
  25     "out"
  26     "dev"
  27     "info"
  28     "doc"
  29   ];
  30
  31   strictDeps = true;
  32   propagatedBuildInputs = lib.optional (!stdenv.hostPlatform.isLinux) libiconv;
  33   buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [
  34     darwin.apple_sdk.frameworks.CoreServices
  35   ];
  36   nativeBuildInputs = [ updateAutotoolsGnuConfigScriptsHook ];
  37
  38   configureFlags = [ "--with-libiconv-prefix=${libiconv}" ];
  39
  40   doCheck = false;
  41
  42   /*
  43     This seems to cause several random failures like these, which I assume
  44     is because of bad or missing target dependencies in their build system:
  45
  46       ./unistdio/test-u16-vasnprintf2.sh: line 16: ./test-u16-vasnprintf1: No such file or directory
  47       FAIL unistdio/test-u16-vasnprintf2.sh (exit status: 1)
  48
  49       FAIL: unistdio/test-u16-vasnprintf3.sh
  50       ======================================
  51
  52       ./unistdio/test-u16-vasnprintf3.sh: line 16: ./test-u16-vasnprintf1: No such file or directory
  53       FAIL unistdio/test-u16-vasnprintf3.sh (exit status: 1)
  54   */
  55   enableParallelChecking = false;
  56   enableParallelBuilding = true;
  57
  58   meta = {
  59     homepage = "https://www.gnu.org/software/libunistring/";
  60
  61     description = "Unicode string library";
  62
  63     longDescription = ''
  64       This library provides functions for manipulating Unicode strings
  65       and for manipulating C strings according to the Unicode
  66       standard.
  67
  68       GNU libunistring is for you if your application involves
  69       non-trivial text processing, such as upper/lower case
  70       conversions, line breaking, operations on words, or more
  71       advanced analysis of text.  Text provided by the user can, in
  72       general, contain characters of all kinds of scripts.  The text
  73       processing functions provided by this library handle all scripts
  74       and all languages.
  75
  76       libunistring is for you if your application already uses the ISO
  77       C / POSIX <ctype.h>, <wctype.h> functions and the text it
  78       operates on is provided by the user and can be in any language.
  79
  80       libunistring is also for you if your application uses Unicode
  81       strings as internal in-memory representation.
  82     '';
  83
  84     license = lib.licenses.lgpl3Plus;
  85
  86     maintainers = [ ];
  87     platforms = lib.platforms.all;
  88   };
  89 })