pkgs/development/libraries/wxsqliteplus/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   wxGTK,
   6   wxsqlite3,
   7   sqlite,
   8   Cocoa,
   9   setfile,
  10 }:
  11
  12 stdenv.mkDerivation rec {
  13   pname = "wxsqliteplus";
  14   version = "0.3.6";
  15
  16   src = fetchFromGitHub {
  17     owner = "guanlisheng";
  18     repo = "wxsqliteplus";
  19     rev = "v${version}";
  20     sha256 = "0mgfq813pli56mar7pdxlhwjf5k10j196rs3jd0nc8b6dkzkzlnf";
  21   };
  22
  23   postPatch = ''
  24     sed -i '/WX_CLEAR_ARRAY/s/$/;/' src/{createtable,sqlite3table}.cpp
  25   '';
  26
  27   buildInputs = [
  28     wxGTK
  29     wxsqlite3
  30     sqlite
  31   ] ++ lib.optional stdenv.hostPlatform.isDarwin Cocoa;
  32
  33   makeFlags =
  34     [
  35       "LDFLAGS=-L${wxsqlite3}/lib"
  36     ]
  37     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  38       "SETFILE=${setfile}/bin/SetFile"
  39     ];
  40
  41   preBuild = ''
  42     sed -ie 's|all: $(LIBPREFIX)wxsqlite$(LIBEXT)|all: |g' Makefile
  43     sed -ie 's|wxsqliteplus$(EXEEXT): $(WXSQLITEPLUS_OBJECTS) $(LIBPREFIX)wxsqlite$(LIBEXT)|wxsqliteplus$(EXEEXT):  $(WXSQLITEPLUS_OBJECTS) |g' Makefile
  44     sed -ie 's|-lwxsqlite |-lwxcode_${
  45       if stdenv.hostPlatform.isDarwin then "osx_cocoau_wxsqlite3-3.2.0" else "gtk3u_wxsqlite3-3.2"
  46     } |g' Makefile
  47   '';
  48
  49   installPhase =
  50     ''
  51       install -D ${lib.optionalString stdenv.hostPlatform.isDarwin "wxsqliteplus.app/Contents/MacOS/"}wxsqliteplus $out/bin/wxsqliteplus
  52     ''
  53     + lib.optionalString stdenv.hostPlatform.isDarwin ''
  54       mkdir -p $out/Applications
  55       mv wxsqliteplus.app $out/Applications/
  56     '';
  57
  58   meta = with lib; {
  59     description = "Simple SQLite database browser built with wxWidgets";
  60     mainProgram = "wxsqliteplus";
  61     homepage = "https://github.com/guanlisheng/wxsqliteplus";
  62     license = licenses.gpl3Plus;
  63     maintainers = [ ];
  64     platforms = platforms.unix;
  65   };
  66 }