pkgs/games/bugdom/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   SDL2,
   6   IOKit,
   7   Foundation,
   8   OpenGL,
   9   cmake,
  10   makeWrapper,
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "bugdom";
  15   version = "1.3.4";
  16
  17   src = fetchFromGitHub {
  18     owner = "jorio";
  19     repo = pname;
  20     rev = version;
  21     hash = "sha256-0c7v5tSqYuqtLOFl4sqD7+naJNqX/wlKHVntkZQGJ8A=";
  22     fetchSubmodules = true;
  23   };
  24
  25   postPatch = lib.optionalString stdenv.hostPlatform.isDarwin ''
  26     # Expects SDL2.framework in specific location, which we don't have
  27     # Passing this in cmakeFlags doesn't work because the path is hard-coded for Darwin
  28     substituteInPlace cmake/FindSDL2.cmake \
  29       --replace 'set(SDL2_LIBRARIES' 'set(SDL2_LIBRARIES "${SDL2}/lib/libSDL2.dylib") #'
  30     # Expects plutil, which we don't have
  31     sed -i '/plutil/d' CMakeLists.txt
  32   '';
  33
  34   buildInputs =
  35     [
  36       SDL2
  37     ]
  38     ++ lib.optionals stdenv.hostPlatform.isDarwin [
  39       IOKit
  40       Foundation
  41       OpenGL
  42     ];
  43
  44   nativeBuildInputs = [
  45     cmake
  46     makeWrapper
  47   ];
  48
  49   cmakeFlags = lib.optionals stdenv.hostPlatform.isDarwin [
  50     "-DCMAKE_OSX_ARCHITECTURES=${stdenv.hostPlatform.darwinArch}"
  51     # Expects SDL2.framework in specific location, which we don't have
  52     "-DSDL2_INCLUDE_DIRS=${SDL2.dev}/include/SDL2"
  53   ];
  54
  55   installPhase =
  56     ''
  57       runHook preInstall
  58
  59     ''
  60     + (
  61       if stdenv.hostPlatform.isDarwin then
  62         ''
  63           mkdir -p $out/{bin,Applications}
  64           mv {,$out/Applications/}Bugdom.app
  65           makeWrapper $out/{Applications/Bugdom.app/Contents/MacOS,bin}/Bugdom
  66         ''
  67       else
  68         ''
  69           mkdir -p $out/share/bugdom
  70           mv Data $out/share/bugdom
  71           install -Dm755 {.,$out/bin}/Bugdom
  72           wrapProgram $out/bin/Bugdom --run "cd $out/share/bugdom"
  73           install -Dm644 $src/packaging/io.jor.bugdom.desktop $out/share/applications/io.jor.bugdom.desktop
  74           install -Dm644 $src/packaging/io.jor.bugdom.png $out/share/pixmaps/io.jor.bugdom.png
  75         ''
  76     )
  77     + ''
  78
  79       runHook postInstall
  80     '';
  81
  82   meta = with lib; {
  83     description = "Port of Bugdom, a 1999 Macintosh game by Pangea Software, for modern operating systems";
  84     homepage = "https://github.com/jorio/Bugdom";
  85     license = with licenses; [ cc-by-sa-40 ];
  86     maintainers = with maintainers; [ lux ];
  87     mainProgram = "Bugdom";
  88     platforms = platforms.unix;
  89   };
  90 }