pkgs/kde/frameworks/kirigami/default.nix

   1 {
   2   stdenv,
   3   mkKdeDerivation,
   4   qtsvg,
   5   qttools,
   6   qtdeclarative,
   7   qt5compat,
   8   qqc2-desktop-style,
   9 }:
  10 # Kirigami has a runtime dependency on qqc2-desktop-style,
  11 # which has a build time dependency on Kirigami.
  12 # So, build qqc2-desktop-style against unwrapped Kirigami,
  13 # and replace all the other Kirigami with a wrapper that
  14 # propagates both Kirigami and qqc2-desktop-style.
  15 # This is a hack, but what can you do.
  16 let
  17   unwrapped = mkKdeDerivation {
  18     pname = "kirigami";
  19
  20     extraNativeBuildInputs = [
  21       qtsvg
  22       qttools
  23     ];
  24     extraBuildInputs = [ qtdeclarative ];
  25     extraPropagatedBuildInputs = [ qt5compat ];
  26   };
  27 in
  28 stdenv.mkDerivation {
  29   pname = "kirigami-wrapped";
  30   inherit (unwrapped) version;
  31
  32   propagatedBuildInputs = [
  33     unwrapped
  34     qqc2-desktop-style
  35   ];
  36
  37   dontUnpack = true;
  38   dontWrapQtApps = true;
  39
  40   passthru = {
  41     inherit unwrapped;
  42   };
  43 }