pkgs/servers/jicofo/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchurl,
   5   dpkg,
   6   jre_headless,
   7   nixosTests,
   8 }:
   9
  10 let
  11   pname = "jicofo";
  12   version = "1.0-1104";
  13   src = fetchurl {
  14     url = "https://download.jitsi.org/stable/${pname}_${version}-1_all.deb";
  15     sha256 = "T4pv3rJLdpTMd8notPxsEq0rbfswxI/1uqrKzV+n5ts=";
  16   };
  17 in
  18 stdenv.mkDerivation {
  19   inherit pname version src;
  20
  21   dontBuild = true;
  22
  23   nativeBuildInputs = [ dpkg ];
  24
  25   installPhase = ''
  26     runHook preInstall
  27     substituteInPlace usr/share/jicofo/jicofo.sh \
  28       --replace "exec java" "exec ${jre_headless}/bin/java"
  29
  30     mkdir -p $out/{share,bin}
  31     mv usr/share/jicofo $out/share/
  32     mv etc $out/
  33     cp ${./logging.properties-journal} $out/etc/jitsi/jicofo/logging.properties-journal
  34     ln -s $out/share/jicofo/jicofo.sh $out/bin/jicofo
  35     runHook postInstall
  36   '';
  37
  38   passthru.tests = {
  39     single-node-smoke-test = nixosTests.jitsi-meet;
  40   };
  41
  42   passthru.updateScript = ./update.sh;
  43
  44   meta = with lib; {
  45     description = "Server side focus component used in Jitsi Meet conferences";
  46     mainProgram = "jicofo";
  47     longDescription = ''
  48       JItsi COnference FOcus is a server side focus component used in Jitsi Meet conferences.
  49     '';
  50     homepage = "https://github.com/jitsi/jicofo";
  51     license = licenses.asl20;
  52     maintainers = teams.jitsi.members;
  53     platforms = platforms.linux;
  54   };
  55 }