pkgs/servers/varnish/default.nix

   1 { lib, stdenv, fetchurl, pcre, pcre2, jemalloc, libunwind, libxslt, groff, ncurses, pkg-config, readline, libedit
   2 , coreutils, python3, makeWrapper, nixosTests }:
   3
   4 let
   5   common = { version, hash, extraNativeBuildInputs ? [] }:
   6     stdenv.mkDerivation rec {
   7       pname = "varnish";
   8       inherit version;
   9
  10       src = fetchurl {
  11         url = "https://varnish-cache.org/_downloads/${pname}-${version}.tgz";
  12         inherit hash;
  13       };
  14
  15       nativeBuildInputs = with python3.pkgs; [ pkg-config docutils sphinx makeWrapper];
  16       buildInputs = [
  17         libxslt groff ncurses readline libedit python3
  18       ]
  19       ++ lib.optional (lib.versionOlder version "7") pcre
  20       ++ lib.optional (lib.versionAtLeast version "7") pcre2
  21       ++ lib.optional stdenv.hostPlatform.isDarwin libunwind
  22       ++ lib.optional stdenv.hostPlatform.isLinux jemalloc;
  23
  24       buildFlags = [ "localstatedir=/var/spool" ];
  25
  26       postPatch = ''
  27         substituteInPlace bin/varnishtest/vtc_main.c --replace /bin/rm "${coreutils}/bin/rm"
  28       '';
  29
  30       postInstall = ''
  31         wrapProgram "$out/sbin/varnishd" --prefix PATH : "${lib.makeBinPath [ stdenv.cc ]}"
  32       '';
  33
  34       # https://github.com/varnishcache/varnish-cache/issues/1875
  35       env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.hostPlatform.isi686 "-fexcess-precision=standard";
  36
  37       outputs = [ "out" "dev" "man" ];
  38
  39       passthru = {
  40         python = python3;
  41         tests = nixosTests."varnish${builtins.replaceStrings [ "." ] [ "" ] (lib.versions.majorMinor version)}";
  42       };
  43
  44       meta = with lib; {
  45         description = "Web application accelerator also known as a caching HTTP reverse proxy";
  46         homepage = "https://www.varnish-cache.org";
  47         license = licenses.bsd2;
  48         maintainers = [ ];
  49         platforms = platforms.unix;
  50       };
  51     };
  52 in
  53 {
  54   # EOL (LTS) TBA
  55   varnish60 = common {
  56     version = "6.0.13";
  57     hash = "sha256-DcpilfnGnUenIIWYxBU4XFkMZoY+vUK/6wijZ7eIqbo=";
  58   };
  59   # EOL 2025-03-15
  60   varnish75 = common {
  61     version = "7.5.0";
  62     hash = "sha256-/KYbmDE54arGHEVG0SoaOrmAfbsdgxRXHjFIyT/3K10=";
  63   };
  64 }