pkgs/tools/misc/logstash/7.x.nix

   1 {
   2   config,
   3   elk7Version,
   4   enableUnfree ? true,
   5   lib,
   6   stdenv,
   7   fetchurl,
   8   makeWrapper,
   9   nixosTests,
  10   jre,
  11 }:
  12
  13 let
  14   info = lib.splitString "-" stdenv.hostPlatform.system;
  15   arch = lib.elemAt info 0;
  16   plat = lib.elemAt info 1;
  17   hashes =
  18     if enableUnfree then
  19       {
  20         x86_64-linux = "sha512-ze0hJxUHCN52bOxUs5upDj64tIE58P2BTow2kaCo6HreRiF9rfTTzNkNr/hCmEgE+/oFbgSEuOQLz+6G373RDQ==";
  21         x86_64-darwin = "sha512-FOFd8d+4UddSGorjuUWW/JbQ5fQH4LU1f1HJLmdbfnb8Q5L4GEveb2LmWNILU8/a85V4HGmD6lL8mCJqH9CULQ==";
  22         aarch64-linux = "sha512-giYqW88/6iT3haXzJVn/+b7uxjYhHq4GERmiq3tMIvjxDyu7B6g+X7JneaTYxhpNdn6gOD/hfXgNv+hFRq6lgg==";
  23       }
  24     else
  25       {
  26         x86_64-linux = "sha512-OC9gx76k+RMdjqcDkrJCNbPYSQameyddaYMxUIB0foVxCmo6UvbdcwZGXRLPPn95in8rYOCjvPoBkmupiQw9xQ==";
  27         x86_64-darwin = "sha512-1OEfEED/jjlT3Fd095Y5VYiWKnovytI3UYCCy1Rs3tEvkZPHYwqIQHfMQYeAvGgUci37ADwEDu8xrSQULHToLw==";
  28         aarch64-linux = "sha512-QWW0AXOMNIXThxpUiRomvINm+917MvGrSDndrEw11IYYuvi0d0dckJiRytfnBbBNoOKpVhB68uOmfjIcZBNpWQ==";
  29       };
  30   this = stdenv.mkDerivation rec {
  31     version = elk7Version;
  32     pname = "logstash${lib.optionalString (!enableUnfree) "-oss"}";
  33
  34     src = fetchurl {
  35       url = "https://artifacts.elastic.co/downloads/logstash/${pname}-${version}-${plat}-${arch}.tar.gz";
  36       hash = hashes.${stdenv.hostPlatform.system} or (throw "Unknown architecture");
  37     };
  38
  39     dontBuild = true;
  40     dontPatchELF = true;
  41     dontStrip = true;
  42     dontPatchShebangs = true;
  43
  44     nativeBuildInputs = [
  45       makeWrapper
  46     ];
  47
  48     buildInputs = [
  49       jre
  50     ];
  51
  52     installPhase = ''
  53       runHook preInstall
  54       mkdir -p $out
  55       cp -r {Gemfile*,modules,vendor,lib,bin,config,data,logstash-core,logstash-core-plugin-api} $out
  56
  57       patchShebangs $out/bin/logstash
  58       patchShebangs $out/bin/logstash-plugin
  59
  60       wrapProgram $out/bin/logstash \
  61          --set JAVA_HOME "${jre}"
  62
  63       wrapProgram $out/bin/logstash-plugin \
  64          --set JAVA_HOME "${jre}"
  65       runHook postInstall
  66     '';
  67
  68     meta = with lib; {
  69       description = "Logstash is a data pipeline that helps you process logs and other event data from a variety of systems";
  70       homepage = "https://www.elastic.co/products/logstash";
  71       sourceProvenance = with sourceTypes; [
  72         fromSource
  73         binaryBytecode # source bundles dependencies as jars
  74         binaryNativeCode # bundled jruby includes native code
  75       ];
  76       license = if enableUnfree then licenses.elastic20 else licenses.asl20;
  77       platforms = platforms.unix;
  78       maintainers = with maintainers; [
  79         offline
  80         basvandijk
  81       ];
  82     };
  83     passthru.tests = lib.optionalAttrs (config.allowUnfree && enableUnfree) (
  84       assert this.drvPath == nixosTests.elk.unfree.ELK-7.elkPackages.logstash.drvPath;
  85       {
  86         elk = nixosTests.elk.unfree.ELK-7;
  87       }
  88     );
  89   };
  90 in
  91 this