pkgs/tools/misc/xburst-tools/default.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchgit,
   5   libusb-compat-0_1,
   6   libusb1,
   7   autoconf,
   8   automake,
   9   libconfuse,
  10   pkg-config,
  11   gccCross ? null,
  12 }:
  13
  14 let
  15   version = "2011-12-26";
  16 in
  17 stdenv.mkDerivation {
  18   pname = "xburst-tools";
  19   inherit version;
  20
  21   src = fetchgit {
  22     url = "git://projects.qi-hardware.com/xburst-tools.git";
  23     rev = "c71ce8e15db25fe49ce8702917cb17720882e341";
  24     sha256 = "1hzdngs1l5ivvwnxjwzc246am6w1mj1aidcf0awh9yw0crzcjnjr";
  25   };
  26
  27   preConfigure = ''
  28     sh autogen.sh
  29   '';
  30
  31   # Workaround build failure on -fno-common toolchains:
  32   #   mipsel-unknown-linux-uclibc-ld: boothandler.o:(.bss+0x8): multiple definition of
  33   #     `start_addr'; main.o:(.bss+0x8): first defined here
  34   NIX_CFLAGS_COMPILE_FOR_TARGET = "-fcommon";
  35
  36   configureFlags = lib.optionals (gccCross != null) [
  37     "--enable-firmware"
  38     "CROSS_COMPILE=${gccCross.targetPrefix}"
  39   ];
  40
  41   hardeningDisable = [
  42     "pic"
  43     "stackprotector"
  44   ];
  45
  46   # Not to strip cross build binaries (this is for the gcc-cross-wrapper)
  47   dontCrossStrip = true;
  48
  49   nativeBuildInputs = [
  50     autoconf
  51     automake
  52     pkg-config
  53   ];
  54   buildInputs = [
  55     libusb-compat-0_1
  56     libusb1
  57     libconfuse
  58   ] ++ lib.optional (gccCross != null) gccCross;
  59
  60   meta = {
  61     broken = stdenv.hostPlatform.isDarwin;
  62     description = "Qi tools to access the Ben Nanonote USB_BOOT mode";
  63     license = lib.licenses.gpl3;
  64     homepage = "http://www.linux-mtd.infradead.org/";
  65     maintainers = [ ];
  66     platforms = lib.platforms.x86_64;
  67   };
  68 }