pkgs/tools/package-management/lix/common.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   version,
   5   suffix ? "",
   6   hash ? null,
   7   src ? fetchFromGitHub {
   8     owner = "lix-project";
   9     repo = "lix";
  10     rev = version;
  11     inherit hash;
  12   },
  13   docCargoHash ? null,
  14   docCargoLock ? null,
  15   patches ? [ ],
  16   maintainers ? lib.teams.lix.members,
  17 }@args:
  18 assert (hash == null) -> (src != null);
  19 {
  20   stdenv,
  21   meson,
  22   bison,
  23   boehmgc,
  24   boost,
  25   brotli,
  26   busybox-sandbox-shell,
  27   bzip2,
  28   callPackage,
  29   curl,
  30   cmake,
  31   doxygen,
  32   editline,
  33   flex,
  34   git,
  35   gtest,
  36   jq,
  37   lib,
  38   libarchive,
  39   libcpuid,
  40   libsodium,
  41   lowdown,
  42   lowdown-unsandboxed,
  43   lsof,
  44   mercurial,
  45   mdbook,
  46   mdbook-linkcheck,
  47   nlohmann_json,
  48   ninja,
  49   openssl,
  50   toml11,
  51   pegtl,
  52   python3,
  53   pkg-config,
  54   rapidcheck,
  55   Security,
  56   sqlite,
  57   util-linuxMinimal,
  58   xz,
  59   nixosTests,
  60   lix-doc ? callPackage ./doc {
  61     inherit src;
  62     version = "${version}${suffix}";
  63     cargoHash = docCargoHash;
  64     cargoLock = docCargoLock;
  65   },
  66
  67   enableDocumentation ? stdenv.hostPlatform == stdenv.buildPlatform,
  68   enableStatic ? stdenv.hostPlatform.isStatic,
  69   withAWS ? !enableStatic && (stdenv.hostPlatform.isLinux || stdenv.hostPlatform.isDarwin),
  70   aws-sdk-cpp,
  71   # RISC-V support in progress https://github.com/seccomp/libseccomp/pull/50
  72   withLibseccomp ? lib.meta.availableOn stdenv.hostPlatform libseccomp,
  73   libseccomp,
  74
  75   confDir,
  76   stateDir,
  77   storeDir,
  78 }:
  79 assert lib.assertMsg (docCargoHash != null || docCargoLock != null)
  80   "Either `lix-doc`'s cargoHash using `docCargoHash` or `lix-doc`'s `cargoLock.lockFile` using `docCargoLock` must be set!";
  81 let
  82   isLegacyParser = lib.versionOlder version "2.91";
  83 in
  84 stdenv.mkDerivation {
  85   pname = "lix";
  86
  87   version = "${version}${suffix}";
  88   VERSION_SUFFIX = suffix;
  89
  90   inherit src patches;
  91
  92   outputs =
  93     [
  94       "out"
  95       "dev"
  96     ]
  97     ++ lib.optionals enableDocumentation [
  98       "man"
  99       "doc"
 100       "devdoc"
 101     ];
 102
 103   strictDeps = true;
 104
 105   nativeBuildInputs =
 106     [
 107       pkg-config
 108       flex
 109       jq
 110       meson
 111       ninja
 112       cmake
 113       python3
 114
 115       # Tests
 116       git
 117       mercurial
 118       jq
 119       lsof
 120     ]
 121     ++ lib.optionals isLegacyParser [ bison ]
 122     ++ lib.optionals enableDocumentation [
 123       (lib.getBin lowdown-unsandboxed)
 124       mdbook
 125       mdbook-linkcheck
 126       doxygen
 127     ]
 128     ++ lib.optionals stdenv.hostPlatform.isLinux [ util-linuxMinimal ];
 129
 130   buildInputs =
 131     [
 132       boost
 133       brotli
 134       bzip2
 135       curl
 136       editline
 137       libsodium
 138       openssl
 139       sqlite
 140       xz
 141       gtest
 142       libarchive
 143       lowdown
 144       rapidcheck
 145       toml11
 146       lix-doc
 147     ]
 148     ++ lib.optionals (!isLegacyParser) [ pegtl ]
 149     ++ lib.optionals stdenv.hostPlatform.isDarwin [ Security ]
 150     ++ lib.optionals (stdenv.hostPlatform.isx86_64) [ libcpuid ]
 151     ++ lib.optionals withLibseccomp [ libseccomp ]
 152     ++ lib.optionals withAWS [ aws-sdk-cpp ];
 153
 154   propagatedBuildInputs = [
 155     boehmgc
 156     nlohmann_json
 157   ];
 158
 159   postPatch = ''
 160     patchShebangs --build tests doc/manual
 161   '';
 162
 163   preConfigure =
 164     # Copy libboost_context so we don't get all of Boost in our closure.
 165     # https://github.com/NixOS/nixpkgs/issues/45462
 166     lib.optionalString (!enableStatic) ''
 167       mkdir -p $out/lib
 168       cp -pd ${boost}/lib/{libboost_context*,libboost_thread*,libboost_system*} $out/lib
 169       rm -f $out/lib/*.a
 170       ${lib.optionalString stdenv.hostPlatform.isLinux ''
 171         chmod u+w $out/lib/*.so.*
 172         patchelf --set-rpath $out/lib:${lib.getLib stdenv.cc.cc}/lib $out/lib/libboost_thread.so.*
 173       ''}
 174       ${lib.optionalString stdenv.hostPlatform.isDarwin ''
 175         for LIB in $out/lib/*.dylib; do
 176           chmod u+w $LIB
 177           install_name_tool -id $LIB $LIB
 178           install_name_tool -delete_rpath ${boost}/lib/ $LIB || true
 179         done
 180         install_name_tool -change ${boost}/lib/libboost_system.dylib $out/lib/libboost_system.dylib $out/lib/libboost_thread.dylib
 181       ''}
 182     '';
 183
 184   # -O3 seems to anger a gcc bug and provide no performance benefit.
 185   # https://gcc.gnu.org/bugzilla/show_bug.cgi?id=114360
 186   # We use -O2 upstream https://gerrit.lix.systems/c/lix/+/554
 187   mesonBuildType = "debugoptimized";
 188
 189   mesonFlags =
 190     [
 191       # Enable LTO, since it improves eval performance a fair amount
 192       # LTO is disabled on static due to strange linking errors
 193       (lib.mesonBool "b_lto" (!stdenv.hostPlatform.isStatic))
 194       (lib.mesonEnable "gc" true)
 195       (lib.mesonBool "enable-tests" true)
 196       (lib.mesonBool "enable-docs" enableDocumentation)
 197       (lib.mesonEnable "internal-api-docs" enableDocumentation)
 198       (lib.mesonBool "enable-embedded-sandbox-shell" (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isStatic))
 199       (lib.mesonEnable "seccomp-sandboxing" withLibseccomp)
 200
 201       (lib.mesonOption "store-dir" storeDir)
 202       (lib.mesonOption "state-dir" stateDir)
 203       (lib.mesonOption "sysconfdir" confDir)
 204     ]
 205     ++ lib.optionals stdenv.hostPlatform.isLinux [
 206       (lib.mesonOption "sandbox-shell" "${busybox-sandbox-shell}/bin/busybox")
 207     ];
 208
 209   ninjaFlags = [ "-v" ];
 210
 211   postInstall =
 212     lib.optionalString enableDocumentation ''
 213       mkdir -p $doc/nix-support
 214       echo "doc manual $doc/share/doc/nix/manual" >> $doc/nix-support/hydra-build-products
 215
 216       mkdir -p $devdoc/nix-support
 217       echo "devdoc internal-api $devdoc/share/doc/nix/internal-api" >> $devdoc/nix-support/hydra-build-products
 218     ''
 219     + lib.optionalString stdenv.hostPlatform.isStatic ''
 220       mkdir -p $out/nix-support
 221       echo "file binary-dist $out/bin/nix" >> $out/nix-support/hydra-build-products
 222     ''
 223     + lib.optionalString stdenv.hostPlatform.isDarwin ''
 224       for lib in liblixutil.dylib liblixexpr.dylib; do
 225         install_name_tool \
 226           -change "${lib.getLib boost}/lib/libboost_context.dylib" \
 227           "$out/lib/libboost_context.dylib" \
 228           "$out/lib/$lib"
 229       done
 230     '';
 231
 232   # This needs to run after _multioutDocs moves the docs to $doc
 233   postFixup = lib.optionalString enableDocumentation ''
 234     mkdir -p $devdoc/share/doc/nix
 235     mv $doc/share/doc/nix/internal-api $devdoc/share/doc/nix
 236   '';
 237
 238   doCheck = true;
 239   mesonCheckFlags = [
 240     "--suite=check"
 241     "--print-errorlogs"
 242   ];
 243   checkInputs = [
 244     gtest
 245     rapidcheck
 246   ];
 247
 248   doInstallCheck = true;
 249   mesonInstallCheckFlags = [
 250     "--suite=installcheck"
 251     "--print-errorlogs"
 252   ];
 253
 254   preInstallCheck = lib.optionalString stdenv.hostPlatform.isDarwin ''
 255     # socket path becomes too long otherwise
 256     export TMPDIR=$NIX_BUILD_TOP
 257     # Prevent crashes in libcurl due to invoking Objective-C `+initialize` methods after `fork`.
 258     # See http://sealiesoftware.com/blog/archive/2017/6/5/Objective-C_and_fork_in_macOS_1013.html.
 259     export OBJC_DISABLE_INITIALIZE_FORK_SAFETY=YES
 260   '';
 261
 262   installCheckPhase = ''
 263     runHook preInstallCheck
 264     flagsArray=($mesonInstallCheckFlags "''${mesonInstallCheckFlagsArray[@]}")
 265     meson test --no-rebuild "''${flagsArray[@]}"
 266     runHook postInstallCheck
 267   '';
 268   hardeningDisable = [
 269     "shadowstack"
 270     # strictoverflow is disabled because we trap on signed overflow instead
 271     "strictoverflow"
 272   ]
 273   # fortify breaks the build with lto and musl for some reason
 274   ++ lib.optional stdenv.hostPlatform.isMusl "fortify";
 275
 276   # hardeningEnable = lib.optionals (!stdenv.hostPlatform.isDarwin) [ "pie" ];
 277   separateDebugInfo = stdenv.hostPlatform.isLinux && !enableStatic;
 278   enableParallelBuilding = true;
 279
 280   # Used by (1) test which has dynamic port assignment.
 281   __darwinAllowLocalNetworking = true;
 282
 283   passthru = {
 284     inherit aws-sdk-cpp boehmgc;
 285     tests = {
 286       misc = nixosTests.nix-misc.lix;
 287     };
 288   };
 289
 290   # point 'nix edit' and ofborg at the file that defines the attribute,
 291   # not this common file.
 292   pos = builtins.unsafeGetAttrPos "version" args;
 293   meta = {
 294     description = "Powerful package manager that makes package management reliable and reproducible";
 295     longDescription = ''
 296       Lix (a fork of Nix) is a powerful package manager for Linux and other Unix systems that
 297       makes package management reliable and reproducible. It provides atomic
 298       upgrades and rollbacks, side-by-side installation of multiple versions of
 299       a package, multi-user package management and easy setup of build
 300       environments.
 301     '';
 302     homepage = "https://lix.systems";
 303     license = lib.licenses.lgpl21Plus;
 304     inherit maintainers;
 305     platforms = lib.platforms.unix;
 306     outputsToInstall = [ "out" ] ++ lib.optional enableDocumentation "man";
 307     mainProgram = "nix";
 308   };
 309 }