pkgs/applications/misc/gpxsee/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , qmake
   5 , nix-update-script
   6 , qtbase
   7 , qttools
   8 , qtlocation ? null # qt5 only
   9 , qtpositioning ? null # qt6 only
  10 , qtserialport
  11 , qtsvg
  12 , wrapQtAppsHook
  13 }:
  14
  15 let
  16   isQt6 = lib.versions.major qtbase.version == "6";
  17 in
  18 stdenv.mkDerivation (finalAttrs: {
  19   pname = "gpxsee";
  20   version = "13.26";
  21
  22   src = fetchFromGitHub {
  23     owner = "tumic0";
  24     repo = "GPXSee";
  25     rev = finalAttrs.version;
  26     hash = "sha256-EIeUcSHJXpd1/90fAPrP9F/DVyZhkcZk8MJd9VO1D70=";
  27   };
  28
  29   buildInputs = [
  30     qtserialport
  31   ] ++ (if isQt6 then [
  32     qtbase
  33     qtpositioning
  34     qtsvg
  35   ] else [
  36     qtlocation
  37   ]);
  38
  39   nativeBuildInputs = [
  40     qmake
  41     qttools
  42     wrapQtAppsHook
  43   ];
  44
  45   preConfigure = ''
  46     lrelease gpxsee.pro
  47   '';
  48
  49   postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
  50     mkdir -p $out/Applications
  51     mv GPXSee.app $out/Applications
  52     mkdir -p $out/bin
  53     ln -s $out/Applications/GPXSee.app/Contents/MacOS/GPXSee $out/bin/gpxsee
  54   '';
  55
  56   passthru = {
  57     updateScript = nix-update-script { };
  58   };
  59
  60   meta = {
  61     broken = isQt6 && stdenv.hostPlatform.isDarwin;
  62     changelog = "https://build.opensuse.org/package/view_file/home:tumic:GPXSee/gpxsee/gpxsee.changes";
  63     description = "GPS log file viewer and analyzer";
  64     mainProgram = "gpxsee";
  65     homepage = "https://www.gpxsee.org/";
  66     license = lib.licenses.gpl3Only;
  67     longDescription = ''
  68       GPXSee is a Qt-based GPS log file viewer and analyzer that supports
  69       all common GPS log file formats.
  70     '';
  71     maintainers = with lib.maintainers; [ womfoo sikmir ];
  72     platforms = lib.platforms.unix;
  73   };
  74 })