pkgs/applications/misc/sc-im/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , pkg-config
   6 , which
   7 , bison
   8 , gnuplot
   9 , libxls
  10 , libxlsxwriter
  11 , libxml2
  12 , libzip
  13 , ncurses
  14 , xlsSupport ? false
  15 }:
  16
  17 stdenv.mkDerivation rec {
  18   pname = "sc-im";
  19   version = "0.8.4";
  20
  21   src = fetchFromGitHub {
  22     owner = "andmarti1424";
  23     repo = "sc-im";
  24     rev = "v${version}";
  25     sha256 = "sha256-nNOifSYbmJjuw6c8TerIQRlhCwbs7GnzD2J7O3vs0gI=";
  26   };
  27
  28   sourceRoot = "${src.name}/src";
  29
  30   nativeBuildInputs = [
  31     makeWrapper
  32     pkg-config
  33     which
  34     bison
  35   ];
  36
  37   buildInputs = [
  38     gnuplot
  39     libxml2
  40     libzip
  41     ncurses
  42   ] ++ lib.optionals xlsSupport [
  43     libxls
  44     libxlsxwriter
  45   ];
  46
  47   makeFlags = [ "prefix=${placeholder "out"}" ];
  48
  49   env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-error=implicit-function-declaration";
  50
  51   postInstall = ''
  52     wrapProgram "$out/bin/sc-im" --prefix PATH : "${lib.makeBinPath [ gnuplot ]}"
  53   '';
  54
  55   meta = with lib; {
  56     changelog = "https://github.com/andmarti1424/sc-im/blob/${src.rev}/CHANGES";
  57     homepage = "https://github.com/andmarti1424/sc-im";
  58     description = "Ncurses spreadsheet program for terminal";
  59     license = licenses.bsdOriginal;
  60     maintainers = with maintainers; [ dotlambda ];
  61     platforms = platforms.unix;
  62   };
  63 }