pkgs/applications/science/logic/cryptoverif/default.nix

   1 { lib, stdenv, fetchurl, ocaml, writeScript }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "cryptoverif";
   5   version = "2.11";
   6
   7   src = fetchurl {
   8     url    = "http://prosecco.gforge.inria.fr/personal/bblanche/cryptoverif/cryptoverif${finalAttrs.version}.tar.gz";
   9     hash = "sha256-duc7t0Qpr1Z2FZEoufdQ7kcBlLbXHO+r9ivEgUxqK9s=";
  10   };
  11
  12   /* Fix up the frontend to load the 'default' cryptoverif library
  13   ** from under $out/libexec. By default, it expects to find the files
  14   ** in $CWD which doesn't work. */
  15   postPatch = ''
  16     substituteInPlace ./src/syntax.ml \
  17       --replace \"default\" \"$out/libexec/default\"
  18   '';
  19
  20   strictDeps = true;
  21
  22   nativeBuildInputs = [ ocaml ];
  23
  24   buildPhase = ''
  25     runHook preBuild
  26
  27     ./build
  28
  29     runHook postBuild
  30   '';
  31
  32   installPhase = ''
  33     runHook preInstall
  34
  35     mkdir -p $out/bin $out/libexec
  36     cp ./cryptoverif   $out/bin
  37     cp ./default.cvl   $out/libexec
  38     cp ./default.ocvl  $out/libexec
  39
  40     runHook postInstall
  41   '';
  42
  43   passthru.updateScript = writeScript "update-cryptoverif" ''
  44     #!/usr/bin/env nix-shell
  45     #!nix-shell -i bash -p common-updater-scripts curl pcre2
  46
  47     set -eu -o pipefail
  48
  49     version="$(curl -s https://bblanche.gitlabpages.inria.fr/CryptoVerif/ |
  50       pcre2grep -o1 '\bCryptoVerif version ([.[:alnum:]]+),')"
  51
  52     update-source-version "$UPDATE_NIX_ATTR_PATH" "$version"
  53   '';
  54
  55   meta = {
  56     description = "Cryptographic protocol verifier in the computational model";
  57     mainProgram = "cryptoverif";
  58     homepage    = "https://bblanche.gitlabpages.inria.fr/CryptoVerif/";
  59     license     = lib.licenses.cecill-b;
  60     platforms   = lib.platforms.unix;
  61     maintainers = [ lib.maintainers.thoughtpolice ];
  62   };
  63 })