pkgs/applications/video/plex-mpv-shim/default.nix

   1 { lib, buildPythonApplication, fetchFromGitHub, fetchpatch, python, mpv, requests, python-mpv-jsonipc, pystray, tkinter
   2 , wrapGAppsHook3, gobject-introspection, mpv-shim-default-shaders }:
   3
   4 buildPythonApplication rec {
   5   pname = "plex-mpv-shim";
   6   version = "1.11.0";
   7
   8   src = fetchFromGitHub {
   9     owner = "iwalton3";
  10     repo = pname;
  11     rev = "refs/tags/v${version}";
  12     sha256 = "sha256-hUGKOJEDZMK5uhHoevFt1ay6QQEcoN4F8cPxln5uMRo=";
  13   };
  14
  15   patches = [
  16     # pull in upstream commit to fix python-mpv dependency name -- remove when version > 1.11.0
  17     (fetchpatch {
  18       url = "https://github.com/iwalton3/plex-mpv-shim/commit/d8643123a8ec79216e02850b08f63b06e4e0a2ea.diff";
  19       hash = "sha256-nc+vwYnAtMjVzL2fIQeTAqhf3HBseL+2pFEtv8zNUXo=";
  20     })
  21   ];
  22
  23   nativeBuildInputs = [
  24     wrapGAppsHook3
  25     gobject-introspection
  26   ];
  27
  28   propagatedBuildInputs = [ mpv requests python-mpv-jsonipc pystray tkinter ];
  29
  30   # needed for pystray to access appindicator using GI
  31   preFixup = ''
  32     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  33   '';
  34   dontWrapGApps = true;
  35
  36   postInstall = ''
  37     # put link to shaders where upstream package expects them
  38     ln -s ${mpv-shim-default-shaders}/share/mpv-shim-default-shaders $out/${python.sitePackages}/plex_mpv_shim/default_shader_pack
  39   '';
  40
  41   # does not contain tests
  42   doCheck = false;
  43
  44   meta = with lib; {
  45     homepage = "https://github.com/iwalton3/plex-mpv-shim";
  46     description = "Allows casting of videos to MPV via the Plex mobile and web app";
  47     maintainers = with maintainers; [ devusb ];
  48     license = licenses.mit;
  49     platforms = platforms.linux;
  50     mainProgram = "plex-mpv-shim";
  51   };
  52 }