pkgs/applications/virtualization/distrobox/default.nix

   1 { stdenvNoCC, lib, fetchFromGitHub, makeWrapper, wget }:
   2
   3 stdenvNoCC.mkDerivation (finalAttrs: {
   4   pname = "distrobox";
   5   version = "1.7.2.1";
   6
   7   src = fetchFromGitHub {
   8     owner = "89luca89";
   9     repo = "distrobox";
  10     rev = finalAttrs.version;
  11     hash = "sha256-H2jeKs0h4ZAcP33HB5jptlubq62cwnjPK2wSlEIfFWA=";
  12   };
  13
  14   dontConfigure = true;
  15   dontBuild = true;
  16
  17   nativeBuildInputs = [ makeWrapper ];
  18
  19   installPhase = ''
  20     runHook preInstall
  21
  22     # https://github.com/89luca89/distrobox/issues/408
  23     substituteInPlace ./distrobox-generate-entry \
  24       --replace-fail 'icon_default="''${HOME}/.local' "icon_default=\"$out"
  25     ./install -P $out
  26
  27     runHook postInstall
  28   '';
  29
  30   # https://github.com/89luca89/distrobox/issues/407
  31   postFixup = ''
  32     wrapProgram "$out/bin/distrobox-generate-entry" \
  33       --prefix PATH ":" ${lib.makeBinPath [ wget ]}
  34
  35     mkdir -p $out/share/distrobox
  36     echo 'container_additional_volumes="/nix:/nix"' > $out/share/distrobox/distrobox.conf
  37   '';
  38
  39   meta = with lib; {
  40     description = "Wrapper around podman or docker to create and start containers";
  41     longDescription = ''
  42       Use any linux distribution inside your terminal. Enable both backward and
  43       forward compatibility with software and freedom to use whatever distribution
  44       you’re more comfortable with
  45     '';
  46     homepage = "https://distrobox.it/";
  47     license = licenses.gpl3Only;
  48     platforms = platforms.linux;
  49     maintainers = with maintainers; [ atila ];
  50   };
  51 })