pkgs/applications/virtualization/lima/bin.nix

   1 { stdenvNoCC
   2 , lib
   3 , fetchurl
   4 , writeScript
   5 , installShellFiles
   6 , qemu
   7 , makeBinaryWrapper
   8 , autoPatchelfHook
   9 }:
  10
  11 let
  12   version = "0.22.0";
  13
  14   dist = {
  15     aarch64-darwin = rec {
  16       archSuffix = "Darwin-arm64";
  17       url = "https://github.com/lima-vm/lima/releases/download/v${version}/lima-${version}-${archSuffix}.tar.gz";
  18       sha256 = "271e0224d3e678450424abd4e6766a14ea52b146824bf8cfac7a0f486ceb2a0c";
  19     };
  20
  21     x86_64-darwin = rec {
  22       archSuffix = "Darwin-x86_64";
  23       url = "https://github.com/lima-vm/lima/releases/download/v${version}/lima-${version}-${archSuffix}.tar.gz";
  24       sha256 = "f2d331ef783e0bb00e193efc3d5c9438df5d284b1cbac771e5d239c3459b2b3d";
  25     };
  26
  27     aarch64-linux = rec {
  28       archSuffix = "Linux-aarch64";
  29       url = "https://github.com/lima-vm/lima/releases/download/v${version}/lima-${version}-${archSuffix}.tar.gz";
  30       sha256 = "8c5c6dc21fae19c5645bf8db8f441aeab7fba21fbe882b2b9db58c126d07846b";
  31     };
  32
  33     x86_64-linux = rec {
  34       archSuffix = "Linux-x86_64";
  35       url = "https://github.com/lima-vm/lima/releases/download/v${version}/lima-${version}-${archSuffix}.tar.gz";
  36       sha256 = "58e66114ae1e991512a86b6952ab3a1ffe0e12e08199a9a3ea13c3d2f24b307e";
  37     };
  38   };
  39 in
  40 stdenvNoCC.mkDerivation {
  41   inherit version;
  42   pname = "lima";
  43   src = fetchurl {
  44     inherit (dist.${stdenvNoCC.hostPlatform.system} or
  45       (throw "Unsupported system: ${stdenvNoCC.hostPlatform.system}")) url sha256;
  46   };
  47
  48   sourceRoot = ".";
  49
  50   nativeBuildInputs = [ makeBinaryWrapper installShellFiles ]
  51     ++ lib.optionals stdenvNoCC.hostPlatform.isLinux [ autoPatchelfHook ];
  52
  53   installPhase = ''
  54     runHook preInstall
  55     mkdir -p $out
  56     cp -r bin share $out
  57     chmod +x $out/bin/limactl
  58     wrapProgram $out/bin/limactl \
  59       --prefix PATH : ${lib.makeBinPath [ qemu ]}
  60
  61     # the shell completion only works with a patched $out/bin/limactl and so
  62     # needs to run after the autoPatchelfHook is executed in postFixup.
  63     doShellCompletion() {
  64       installShellCompletion --cmd limactl \
  65         --bash <($out/bin/limactl completion bash) \
  66         --fish <($out/bin/limactl completion fish) \
  67         --zsh <($out/bin/limactl completion zsh)
  68     }
  69     postFixupHooks+=(doShellCompletion)
  70
  71     runHook postInstall
  72   '';
  73
  74   doInstallCheck = true;
  75   installCheckPhase = ''
  76     USER=nix $out/bin/limactl validate $out/share/lima/examples/default.yaml
  77     USER=nix $out/bin/limactl validate $out/share/lima/examples/experimental/vz.yaml
  78   '';
  79
  80   # Stripping removes entitlements of the binary on Darwin making it non-operational.
  81   # Therefore, disable stripping on Darwin.
  82   dontStrip = stdenvNoCC.hostPlatform.isDarwin;
  83
  84   passthru.updateScript =
  85     let
  86       lima-bin = builtins.toString ./bin.nix;
  87     in
  88     writeScript "update-lima-bin.sh" ''
  89       #!/usr/bin/env nix-shell
  90       #!nix-shell -i bash -p common-updater-scripts curl jq gawk
  91
  92       set -eou pipefail
  93
  94       LATEST_VERSION=$(curl -H "Accept: application/vnd.github+json" -Ls https://api.github.com/repos/lima-vm/lima/releases/latest | jq -r .tag_name | cut -c 2-)
  95       curl -Ls -o SHA256SUMS https://github.com/lima-vm/lima/releases/download/v$LATEST_VERSION/SHA256SUMS
  96       AARCH64_DARWIN_SHA256=$(cat SHA256SUMS | awk '/Darwin-arm64/{print $1}')
  97       X86_64_DARWIN_SHA256=$(cat SHA256SUMS | awk '/Darwin-x86_64/{print $1}')
  98       AARCH64_LINUX_SHA256=$(cat SHA256SUMS | awk '/Linux-aarch64/{print $1}')
  99       X86_64_LINUX_SHA256=$(cat SHA256SUMS | awk '/Linux-x86_64/{print $1}')
 100
 101       # reset version first so that all platforms are always updated and in sync
 102       update-source-version lima-bin $LATEST_VERSION $AARCH64_DARWIN_SHA256 --file=${lima-bin} --ignore-same-version --system=aarch64-darwin
 103       update-source-version lima-bin $LATEST_VERSION $X86_64_DARWIN_SHA256 --file=${lima-bin} --ignore-same-version --system=x86_64-darwin
 104       update-source-version lima-bin $LATEST_VERSION $AARCH64_LINUX_SHA256 --file=${lima-bin} --ignore-same-version --system=aarch64-linux
 105       update-source-version lima-bin $LATEST_VERSION $X86_64_LINUX_SHA256 --file=${lima-bin} --ignore-same-version --system=x86_64-linux
 106       rm SHA256SUMS
 107     '';
 108
 109   meta = with lib; {
 110     homepage = "https://github.com/lima-vm/lima";
 111     description = "Linux virtual machines (on macOS, in most cases)";
 112     license = licenses.asl20;
 113     maintainers = with maintainers; [ tricktron ];
 114     platforms = platforms.linux ++ platforms.darwin;
 115   };
 116 }