pkgs/tools/audio/piper/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4
   5 # build time
   6 , cmake
   7 , pkg-config
   8
   9 # runtime
  10 , fmt
  11 , onnxruntime
  12 , pcaudiolib
  13 , piper-phonemize
  14 , spdlog
  15
  16 # tests
  17 , piper-train
  18 }:
  19
  20 stdenv.mkDerivation (finalAttrs: {
  21   pname = "piper";
  22   version = "2023.11.14-2";
  23
  24   src = fetchFromGitHub {
  25     owner = "rhasspy";
  26     repo = "piper";
  27     rev = "refs/tags/${finalAttrs.version}";
  28     hash = "sha256-3ynWyNcdf1ffU3VoDqrEMrm5Jo5Zc5YJcVqwLreRCsI=";
  29   };
  30
  31   nativeBuildInputs = [
  32     cmake
  33     pkg-config
  34   ];
  35
  36   cmakeFlags = [
  37     "-DFMT_DIR=${fmt}"
  38     "-DSPDLOG_DIR=${spdlog.src}"
  39     "-DPIPER_PHONEMIZE_DIR=${piper-phonemize}"
  40   ];
  41
  42   buildInputs = [
  43     onnxruntime
  44     pcaudiolib
  45     piper-phonemize
  46     piper-phonemize.espeak-ng
  47     spdlog
  48   ];
  49
  50   env.NIX_CFLAGS_COMPILE = builtins.toString [
  51     "-isystem ${lib.getDev piper-phonemize}/include/piper-phonemize"
  52   ];
  53
  54   installPhase = ''
  55     runHook preInstall
  56
  57     mkdir -p $out/bin
  58     install -m 0755 piper $out/bin
  59
  60     runHook postInstall
  61   '';
  62
  63   passthru.tests = {
  64     inherit piper-train;
  65   };
  66
  67   meta = with lib; {
  68     changelog = "https://github.com/rhasspy/piper/releases/tag/v${finalAttrs.version}";
  69     description = "Fast, local neural text to speech system";
  70     homepage = "https://github.com/rhasspy/piper";
  71     license = licenses.mit;
  72     maintainers = with maintainers; [ hexa ];
  73     mainProgram = "piper";
  74   };
  75 })