pkgs/tools/inputmethods/fcitx5/fcitx5-skk.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , pkg-config
   5 , cmake
   6 , extra-cmake-modules
   7 , gettext
   8 , fcitx5
   9 , fcitx5-qt
  10 , libskk
  11 , qtbase
  12 , skkDictionaries
  13 , enableQt ? false
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "fcitx5-skk";
  18   version = "5.1.5";
  19
  20   src = fetchFromGitHub {
  21     owner = "fcitx";
  22     repo = pname;
  23     rev = version;
  24     hash = "sha256-wv5vX9eFlBUY7x4v9U+OuhKgX6V/b3iTaCvAIwJO10o=";
  25   };
  26
  27   nativeBuildInputs = [
  28     cmake
  29     extra-cmake-modules
  30     gettext
  31     pkg-config
  32   ];
  33
  34   buildInputs = [
  35     fcitx5
  36     libskk
  37   ] ++ lib.optionals enableQt [
  38     fcitx5-qt
  39     qtbase
  40   ];
  41
  42   cmakeFlags = [
  43     (lib.cmakeBool "ENABLE_QT" enableQt)
  44     (lib.cmakeBool "USE_QT6" (lib.versions.major qtbase.version == "6"))
  45     "-DSKK_DEFAULT_PATH=${skkDictionaries.l}/share/skk/SKK-JISYO.L"
  46   ];
  47
  48   dontWrapQtApps = true;
  49
  50   meta = with lib; {
  51     description = "Input method engine for Fcitx5, which uses libskk as its backend";
  52     homepage = "https://github.com/fcitx/fcitx5-skk";
  53     license = licenses.gpl3Plus;
  54     maintainers = with maintainers; [ milran ];
  55     platforms = platforms.linux;
  56   };
  57 }