pkgs/tools/inputmethods/ibus-engines/ibus-table/default.nix

   1 { lib, stdenv, fetchFromGitHub
   2 , autoreconfHook, docbook2x, pkg-config
   3 , gtk3, dconf, gobject-introspection
   4 , ibus, python3, wrapGAppsHook3 }:
   5
   6 stdenv.mkDerivation rec {
   7   pname = "ibus-table";
   8   version = "1.17.8";
   9
  10   src = fetchFromGitHub {
  11     owner  = "kaio";
  12     repo   = "ibus-table";
  13     rev    = version;
  14     sha256 = "sha256-bPHwpTrDCLil6xNBr7lKAMP71koFlZvPc2vpDuwzZzM=";
  15   };
  16
  17   postPatch = ''
  18     # Data paths will be set at run-time.
  19     sed -e "/export IBUS_TABLE_LIB_LOCATION=/ s/^.*$//" \
  20         -e "/export IBUS_TABLE_LOCATION=/ s/^.*$//" \
  21         -i "engine/ibus-engine-table.in"
  22     sed -e "/export IBUS_TABLE_BIN_PATH=/ s/^.*$//" \
  23         -e "/export IBUS_TABLE_DATA_DIR=/ s/^.*$//" \
  24         -i "engine/ibus-table-createdb.in"
  25     sed -e "/export IBUS_PREFIX=/ s/^.*$//" \
  26         -e "/export IBUS_DATAROOTDIR=/ s/^.$//" \
  27         -e "/export IBUS_LOCALEDIR=/ s/^.$//" \
  28         -i "setup/ibus-setup-table.in"
  29     substituteInPlace engine/tabcreatedb.py --replace '/usr/share/ibus-table' $out/share/ibus-table
  30     substituteInPlace engine/ibus_table_location.py \
  31       --replace '/usr/libexec' $out/libexec \
  32       --replace '/usr/share/ibus-table/' $out/share/ibus-table/
  33   '';
  34
  35   buildInputs = [
  36     dconf
  37     gtk3
  38     ibus
  39     (python3.withPackages (pypkgs: with pypkgs; [
  40       dbus-python
  41       pygobject3
  42       (toPythonModule ibus)
  43     ]))
  44   ];
  45
  46   nativeBuildInputs = [
  47     autoreconfHook
  48     docbook2x
  49     pkg-config
  50     gobject-introspection
  51     wrapGAppsHook3
  52   ];
  53
  54   postUnpack = ''
  55     substituteInPlace $sourceRoot/engine/Makefile.am \
  56       --replace "docbook2man" "docbook2man --sgml"
  57   '';
  58
  59   meta = with lib; {
  60     isIbusEngine = true;
  61     description  = "IBus framework for table-based input methods";
  62     mainProgram = "ibus-table-createdb";
  63     homepage     = "https://github.com/kaio/ibus-table/wiki";
  64     license      = licenses.lgpl21;
  65     platforms    = platforms.linux;
  66     maintainers  = with maintainers; [ mudri ];
  67   };
  68 }