pkgs/tools/misc/svtplay-dl/default.nix

   1 {
   2   lib,
   3   fetchFromGitHub,
   4   installShellFiles,
   5   python3Packages,
   6   perl,
   7   ffmpeg,
   8 }:
   9
  10 let
  11
  12   inherit (python3Packages)
  13     buildPythonApplication
  14     setuptools
  15     requests
  16     pysocks
  17     cryptography
  18     pyyaml
  19     pytestCheckHook
  20     mock
  21     requests-mock
  22     ;
  23
  24   version = "4.97.1";
  25
  26 in
  27
  28 buildPythonApplication {
  29   pname = "svtplay-dl";
  30   inherit version;
  31   pyproject = true;
  32
  33   src = fetchFromGitHub {
  34     owner = "spaam";
  35     repo = "svtplay-dl";
  36     rev = version;
  37     hash = "sha256-9h3hHRRL7DKeCpEXL5w72hYi1nTS+a+x5e9ArMmVgYQ=";
  38   };
  39
  40   build-system = [ setuptools ];
  41
  42   dependencies = [
  43     requests
  44     pysocks
  45     cryptography
  46     pyyaml
  47   ];
  48
  49   nativeBuildInputs = [
  50     # For `pod2man(1)`.
  51     perl
  52     installShellFiles
  53   ];
  54
  55   nativeCheckInputs = [
  56     pytestCheckHook
  57     mock
  58     requests-mock
  59   ];
  60
  61   pytestFlagsArray = [
  62     "--doctest-modules"
  63     "lib"
  64   ];
  65
  66   postBuild = ''
  67     make svtplay-dl.1
  68   '';
  69
  70   postInstall = ''
  71     installManPage svtplay-dl.1
  72     makeWrapperArgs+=(--prefix PATH : "${lib.makeBinPath [ ffmpeg ]}")
  73   '';
  74
  75   postInstallCheck = ''
  76     $out/bin/svtplay-dl --help > /dev/null
  77   '';
  78
  79   meta = {
  80     homepage = "https://github.com/spaam/svtplay-dl";
  81     description = "Command-line tool to download videos from svtplay.se and other sites";
  82     license = lib.licenses.mit;
  83     platforms = lib.platforms.unix;
  84     mainProgram = "svtplay-dl";
  85   };
  86 }