pkgs/tools/misc/tvnamer/default.nix

   1 { lib
   2 , python3
   3 , fetchPypi
   4 }:
   5
   6 let
   7   python' = python3.override {
   8     self = python';
   9     packageOverrides = final: prev: rec {
  10       # tvdb_api v3.1.0 has a hard requirement on requests-cache < 0.6
  11       requests-cache = prev.requests-cache.overridePythonAttrs (oldAttrs: rec {
  12         version = "0.5.2";
  13         src = fetchPypi {
  14           inherit (oldAttrs) pname;
  15           inherit version;
  16           sha256 = "sha256-gTAjJpaGBF+OAeIonMHn6a5asi3dHihJqQk6s6tycOs=";
  17         };
  18
  19         nativeBuildInputs = with final; [
  20           setuptools
  21         ];
  22
  23         # too many changes have been made to requests-cache based on version 0.6 so
  24         # simply disable tests
  25         doCheck = false;
  26       });
  27     };
  28   };
  29
  30   pypkgs = python'.pkgs;
  31
  32 in
  33 pypkgs.buildPythonApplication rec {
  34   pname = "tvnamer";
  35   version = "3.0.4";
  36
  37   src = fetchPypi {
  38     inherit pname version;
  39     sha256 = "dc2ea8188df6ac56439343630466b874c57756dd0b2538dd8e7905048f425f04";
  40   };
  41
  42   propagatedBuildInputs = with pypkgs; [ tvdb-api ];
  43
  44   # no tests from pypi
  45   doCheck = false;
  46
  47   meta = with lib; {
  48     description = "Automatic TV episode file renamer, uses data from thetvdb.com via tvdb_api";
  49     homepage = "https://github.com/dbr/tvnamer";
  50     license = licenses.unlicense;
  51     maintainers = with maintainers; [ peterhoeg ];
  52     mainProgram = "tvnamer";
  53   };
  54 }