pkgs/tools/package-management/cde/default.nix

   1 { lib, stdenv, fetchFromGitHub, libxcrypt }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "cde";
   5   version = "0.1";
   6
   7   src = fetchFromGitHub {
   8     owner = "usnistgov";
   9     repo = "corr-CDE";
  10     rev = "v${version}";
  11     sha256 = "sha256-s375gtqBWx0GGXALXR+fN4bb3tmpvPNu/3bNz+75UWU=";
  12   };
  13
  14   # The build is small, so there should be no problem
  15   # running this locally. There is also a use case for
  16   # older systems, where modern binaries might not be
  17   # useful.
  18   preferLocalBuild = true;
  19
  20   buildInputs = [ libxcrypt ];
  21
  22   patchBuild = ''
  23     sed -i -e '/install/d' $src/Makefile
  24   '';
  25
  26   preBuild = ''
  27     patchShebangs .
  28   '';
  29
  30   # Workaround build failure on -fno-common toolchains like upstream
  31   # gcc-10. Otherwise build fails as:
  32   #   ld: ../readelf-mini/libreadelf-mini.a(dwarf.o):/build/source/readelf-mini/dwarf.c:64:
  33   #     multiple definition of `do_wide'; ../readelf-mini/libreadelf-mini.a(readelf-mini.o):/build/source/readelf-mini/readelf-mini.c:170: first defined here
  34   env.NIX_CFLAGS_COMPILE = "-fcommon";
  35
  36   installPhase = ''
  37     install -d $out/bin
  38     install -t $out/bin cde cde-exec
  39   '';
  40
  41   meta = with lib; {
  42     homepage = "https://github.com/usnistgov/corr-CDE";
  43     description = "Packaging tool for building portable packages";
  44     license = licenses.gpl3Plus;
  45     maintainers = [ maintainers.rlupton20 ];
  46     platforms = platforms.linux;
  47     # error: architecture aarch64 is not supported by bundled strace
  48     badPlatforms = [ "aarch64-linux" ];
  49   };
  50 }